dnl $Id: configure.in,v 1.11 1993/10/18 13:31:44 ceder Exp $
dnl Configuration for LysKOM
AC_REVISION($Revision: 1.11 $)
AC_INIT(src/server/lyskomd.h)
AC_PROG_CC
AC_SUBST(CFLAGS)
AC_SUBST(DEPENDFLAG)
include_current=-I.
[if test -n "$GCC"; then
	test -n "$verbose" && echo adding -g -O -ansi -Wall -pipe
	CFLAGS="$CFLAGS -g -O -Wall -ansi -pipe"
	DEPENDFLAG=-MM
else
	test -n "$verbose" && echo adding -g
	CFLAGS="$CFLAGS -g"
	case "$CC" in
		*vcc) DEPENDFLAG=-Em
			include_current='-I`pwd`';;
		*) DEPENDFLAG=-M;;
	esac
fi
test -n "$verbose" && echo Setting DEPENDFLAG to $DEPENDFLAG]
AC_AIX
AC_ISC_POSIX
AC_MINIX
AC_DYNIX_SEQ
AC_IRIX_SUN
AC_CONST
AC_STDC_HEADERS
AC_COMPILE_CHECK([HPUX and struct sockaddr], dnl
[#include <sys/socket.h>], dnl
[struct sockaddr foo;], dnl
[test -n "$verbose" && echo '	'No action needed], dnl IF FOUND
[test -n "$verbose" && echo '	'Checking for a fix; dnl IF NOT FOUND
AC_COMPILE_CHECK([_HPUX_SOURCE to fix problems], dnl
[#define _HPUX_SOURCE
#include <sys/socket.h>], dnl
[struct sockaddr foo;], dnl
AC_DEFINE(_HPUX_SOURCE), dnl
[test -n "$verbose" && echo '	'Problem remains])])dnl
[SRCTOPDIR=`cd $srcdir;pwd`]
[BUILDTOPDIR=`pwd`]
dnl
dnl descend(foo) will define FOO_DESCEND as a Makefile excerpt
dnl
define([descend], [AC_SUBST(translit($1, [a-z], [A-Z])[_DESCEND])
translit($1, [a-z], [A-Z])[_DESCEND='.PHONY: ]$1 \
$1: [do]$1 \
	[for i in DuMmY $(SUBDIRS); do \\\
		if test -d $$i ; then \\\
			echo making] $1 [in directory $$i; \\\
			(cd $$i; $(MAKE) ] $1 [)\\\
		fi; \\\
	done\
']])dnl
dnl
descend(binaries)
descend(mostlyclean)
descend(clean)
descend(distclean)
descend(realclean)
descend(pure)
descend(depend)
descend(includes)
descend(libraries)
descend(install)
dnl
dnl  Define CLEAN to handle all the "make *clean" rules.
dnl
AC_SUBST(CLEAN)
[CLEAN="$MOSTLYCLEAN_DESCEND\\
$CLEAN_DESCEND\\
$DISTCLEAN_DESCEND\\
$REALCLEAN_DESCEND\\
$PURE_DESCEND"]
dnl
dnl  Enhance "make depend"
dnl
[DEPEND_DESCEND="dependencies:\\
	touch dependencies\\
\\
$DEPEND_DESCEND\\
"]
AC_PROG_INSTALL
AC_PROG_RANLIB
AC_PROG_AWK
AC_LN_S
AC_PROG_YACC
AC_PROG_LEX
AC_PROGRAMS_CHECK(SED, sed)
AC_HAVE_HEADERS(string.h memory.h strings.h sys/param.h sys/time.h)
AC_HAVE_HEADERS(stdarg.h stdlib.h stddef.h locale.h)
AC_TIME_WITH_SYS_TIME
dnl AC_USG is used by regex, but is obsolete.
AC_USG
AC_ALLOCA
AC_HAVE_LIBRARY(resolv) dnl Host name lookup.
AC_HAVE_LIBRARY(authuser) dnl User authentication according to RFC 931.
AC_HAVE_LIBRARY(socket) dnl socket() et c on Solaris 2.
AC_HAVE_LIBRARY(nsl) dnl Low-level networking code on Solaris 2.
AC_HAVE_LIBRARY(i) dnl For setlocale() on Ultrix.
AC_HAVE_FUNCS(difftime getdtablesize sysconf getcwd vfprintf)
AC_REPLACE_FUNCS(memcpy difftime strerror remove strchr memset memchr)
[DEFS="$DEFS -DBUGGY_INET_NTOA=1 -DENCRYPT_PASSWORDS=1 -DSERVER=1"]
AC_SUBST(ALL_DESCEND)
[ALL_DESCEND="$INCLUDES_DESCEND\\
$LIBRARIES_DESCEND\\
$BINARIES_DESCEND\\
$INSTALL_DESCEND\\
$DEPEND_DESCEND\\
$CLEAN\\
"]
[CFLAGS="$CFLAGS $include_current -I\$(srcdir)"]
[CFLAGS="$CFLAGS -I$BUILDTOPDIR/include -I$BUILDTOPDIR/include/server"]
[CFLAGS="$CFLAGS -I/usr/local/include"]
dnl Adding DEFS to CFLAGS must be the last thing done to CFLAGS,
dnl since it breaks the compile tests generated by autoconf.
dnl +++This probably violates the GNU Coding Standards as well,
dnl and should be fixed before the upcoming release.
[CFLAGS="$CFLAGS \$(DEFS)" ]
AC_SUBST(STDLYSKOM)
[STDLYSKOM="# BEGIN section from @STDLYSKOM@\\
SHELL = /bin/sh \\
\\
AWK = $AWK\\
CC = $CC\\
CFLAGS = $CFLAGS\\
DEPENDFLAG = $DEPENDFLAG\\
INSTALL = $INSTALL\\
INSTALL_DATA = $INSTALL_DATA\\
INSTALL_PROGRAM = $INSTALL_PROGRAM\\
LEX = $LEX\\
MKDIR = mkdir\\
RANLIB = $RANLIB\\
RM = rm -f\\
SED = $SED\\
SYMLINK = $LN_S\\
TOUCHLIB = $RANLIB\\
YACC = $YACC\\
\\
INCLUDEDIR = $BUILDTOPDIR/include\\
LIBDIR = $BUILDTOPDIR/lib\\
prefix = /usr/lyskom\\
exec_prefix = \$(prefix)\\
bindir = \$(exec_prefix)/bin\\
dbdir = \$(exec_prefix)/db\\
etcdir = \$(exec_prefix)/etc\\
coredir = \$(exec_prefix)/cores\\
\\
DEFS = $DEFS\\
LDFLAGS = $LDFLAGS\\
SCRIPTDIR = $SRCTOPDIR/scripts\\
GENERIC-MOSTLYCLEAN = *.o lib*.a core temp-Makefile temp-?-Makefile\\
GENERIC-DISTCLEAN = *~ .\\\\#* TAGS dependencies Makefile\\
# END section from @STDLYSKOM@\\
"]
AC_OUTPUT(Makefile
doc/Makefile
doc/man/Makefile
scripts/Makefile
src/Makefile
src/include/Makefile
src/include/server/Makefile
src/libraries/Makefile
src/libraries/libansi/Makefile
src/libraries/libcommon/Makefile
src/libraries/libisc-new/Makefile
src/libraries/libisc-new/src/Makefile
src/libraries/libmisc/Makefile
src/libraries/regex/Makefile
src/libraries/regex/doc/Makefile
src/libraries/regex/test/Makefile
src/server/Makefile)