dnl Process this file with autoconf to produce a configure script.
dnl This configure.in was derived from the configure.in in the
dnl GNU regex package, rel 0.11.  Since LysKOM uses that package,
dnl this configure script must include everything it needs.
AC_REVISION($Id: configure.in,v 1.5 1993/10/12 16:31:15 ceder Exp $)
AC_INIT(src/server/lyskomd.h)
AC_PROG_CC
AC_AIX
AC_ISC_POSIX
AC_MINIX
AC_DYNIX_SEQ
AC_IRIX_SUN
[SRCTOPDIR=`cd $srcdir;pwd`]
[BUILDTOPDIR=`pwd`]
dnl
dnl descend(foo) will define FOO_DESCEND as a Makefile excerpt
dnl
define([descend], [AC_SUBST(translit($1, [a-z], [A-Z])[_DESCEND])
translit($1, [a-z], [A-Z])[_DESCEND='.PHONY: ]$1 \
$1: [do]$1 \
	[for i in DuMmY $(SUBDIRS); do \\\
		if test -d $$i ; then \\\
			echo making] $1 [in directory $$i; \\\
			(cd $$i; $(MAKE) ] $1 [)\\\
		fi; \\\
	done\
']])dnl
dnl
descend(binaries)
descend(mostlyclean)
descend(clean)
descend(distclean)
descend(realclean)
descend(pure)
descend(depend)
descend(includes)
descend(libraries)
descend(install)
dnl
dnl  Define CLEAN to handle all the "make *clean" rules.
dnl
AC_SUBST(CLEAN)
[CLEAN="$MOSTLYCLEAN_DESCEND\\
$CLEAN_DESCEND\\
$DISTCLEAN_DESCEND\\
$REALCLEAN_DESCEND\\
$PURE_DESCEND"]
dnl
dnl  Enhance "make depend"
dnl
[DEPEND_DESCEND="dependencies:\\
	touch dependencies\\
\\
$DEPEND_DESCEND\\
"]
AC_PROG_INSTALL
AC_PROG_RANLIB
AC_PROG_AWK
AC_LN_S
AC_PROG_YACC
AC_PROG_LEX
AC_STDC_HEADERS
AC_PROGRAMS_CHECK(SED, /usr/gnu/bin/sed /usr/local/gnu/bin/sed sed)
AC_HAVE_HEADERS(string.h memory.h sys/param.h sys/time.h stdlib.h locale.h)
AC_TIME_WITH_SYS_TIME
dnl AC_USG is used by regex, but is obsolete.
AC_USG
AC_ALLOCA
AC_HAVE_LIBRARY(resolv)
AC_HAVE_LIBRARY(authuser)
AC_HAVE_LIBRARY(socket)
AC_HAVE_LIBRARY(nsl)
AC_HAVE_FUNCS(difftime getdtablesize sysconf getcwd)
AC_REPLACE_FUNCS(memcpy difftime strerror)
[DEFS="$DEFS -DBUGGY_INET_NTOA=1 -DENCRYPT_PASSWORDS=1 -DSERVER=1"]
AC_SUBST(ALL_DESCEND)
[ALL_DESCEND="$INCLUDES_DESCEND\\
$LIBRARIES_DESCEND\\
$BINARIES_DESCEND\\
$INSTALL_DESCEND\\
$DEPEND_DESCEND\\
$CLEAN\\
"]
AC_SUBST(CFLAGS)
[CFLAGS="$CFLAGS -I$BUILDTOPDIR/include -I$BUILDTOPDIR/include/server -I. "]
[CFLAGS="$CFLAGS -g -O -Wall -ansi -pipe \$(DEFS)" ]
AC_SUBST(STDLYSKOM)
[STDLYSKOM="# BEGIN section from @STDLYSKOM@\\
SHELL = /bin/sh \\
\\
AWK = $AWK\\
CC = $CC\\
CFLAGS = $CFLAGS\\
INSTALL = $INSTALL\\
INSTALL_DATA = $INSTALL_DATA\\
INSTALL_PROGRAM = $INSTALL_PROGRAM\\
LEX = $LEX\\
MKDIR = mkdir\\
RANLIB = $RANLIB\\
RM = rm -f\\
SED = $SED\\
SYMLINK = $LN_S\\
TOUCHLIB = $RANLIB\\
YACC = $YACC\\
\\
INCLUDEDIR = $BUILDTOPDIR/include\\
LIBDIR = $BUILDTOPDIR/lib\\
prefix = /usr/lyskom\\
exec_prefix = \$(prefix)\\
bindir = \$(exec_prefix)/bin\\
dbdir = \$(exec_prefix)/db\\
etcdir = \$(exec_prefix)/etc\\
coredir = \$(exec_prefix)/cores\\
\\
DEFS = $DEFS\\
LDFLAGS = $LDFLAGS\\
SCRIPTDIR = $SRCTOPDIR/scripts\\
GENERIC-MOSTLYCLEAN = *.o lib*.a core temp-Makefile temp-?-Makefile\\
GENERIC-DISTCLEAN = *~ TAGS dependencies Makefile\\
# END section from @STDLYSKOM@\\
"]
[mkdir $BUILDTOPDIR/include]
[mkdir $BUILDTOPDIR/lib]
AC_OUTPUT(Makefile
doc/Makefile
doc/man/Makefile
scripts/Makefile
src/Makefile
src/include/Makefile
src/include/server/Makefile
src/libraries/Makefile
src/libraries/libansi/Makefile
src/libraries/libcommon/Makefile
src/libraries/libisc-new/Makefile
src/libraries/libisc-new/src/Makefile
src/libraries/libmisc/Makefile
src/libraries/regex/Makefile
src/libraries/regex/doc/Makefile
src/libraries/regex/test/Makefile
src/server/Makefile
)