dnl $Id: configure.in,v 1.26 1995/01/08 11:14:07 ceder Exp $
dnl Configuration for LysKOM
dnl Copyright (C) 1993, 1994, 1995  Lysator Academic Computer Association.
dnl
dnl This program is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 2, or (at your option)
dnl any later version.
dnl
dnl This program is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License
dnl along with this program; if not, write to the Free Software
dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
dnl
dnl Please mail bug reports to bug-lyskom@lysator.liu.se. 
dnl
AC_REVISION($Revision: 1.26 $)
AC_INIT(src/server/lyskomd.h)
AC_PREFIX_DEFAULT(/usr/lyskom)
AC_PROG_CC
AC_SUBST(CFLAGS)
AC_SUBST(CPPFLAGS)
AC_SUBST(LDFLAGS)
AC_SUBST(DEPENDFLAG)
AC_SUBST(INCLUDE_CURRENT)
INCLUDE_CURRENT=-I.
AC_AIX
AC_ISC_POSIX
AC_MINIX
[if test -n "$GCC"; then
	CFLAGS="$CFLAGS -Wall -ansi"
	] KOM_COMPILER_CC_ACCEPTS([-pipe]) [
	DEPENDFLAG=-MM
else
	case "$CC" in
		*vcc) DEPENDFLAG=-Em
			INCLUDE_CURRENT='-I`pwd`';;
		*) DEPENDFLAG=-M;;
	esac
fi]
AC_MSG_CHECKING([flag to get dependencies])
AC_MSG_RESULT([$DEPENDFLAG])
AC_C_CONST
AC_HEADER_STDC
AC_TYPE_PID_T
AC_MSG_CHECKING([if _HPUX_SOURCE needs to be defined])
AC_CACHE_VAL([kom_cv_sys_hpux_source],
[AC_TRY_LINK(
[#include <sys/types.h>
#include <sys/socket.h>],
[struct sockaddr foo;],
[kom_cv_sys_hpux_source=no], dnl IF FOUND
[dnl IF NOT FOUND
AC_TRY_LINK(
[#define _HPUX_SOURCE
#include <sys/types.h>
#include <sys/socket.h>],
[struct sockaddr foo;],
[kom_cv_sys_hpux_source=yes],
[kom_cv_sys_hpux_source=no])])])
AC_MSG_RESULT($kom_cv_sys_hpux_source)
[if test $kom_cv_sys_hpux_source = yes ; then]
  AC_DEFINE(_HPUX_SOURCE)
[fi]
AC_SUBST(SRCTOPDIR)
[SRCTOPDIR=`cd $srcdir;pwd`]
AC_SUBST(BUILDTOPDIR)
[BUILDTOPDIR=`pwd`]
AC_CONFIG_AUX_DIR(scripts)
AC_PROG_INSTALL
AC_PROG_RANLIB
AC_PROG_AWK
AC_PROG_LN_S
AC_PROG_YACC
AC_PROG_LEX
AC_CHECK_PROGS(SED, sed)
AC_CHECK_HEADERS(string.h memory.h strings.h sys/param.h sys/time.h)
AC_CHECK_HEADERS(stdarg.h stdlib.h stddef.h locale.h sys/resource.h)
AC_HEADER_TIME
AC_FUNC_ALLOCA
AC_CHECK_LIB(resolv,main) dnl Host name lookup.
AC_CHECK_LIB(authuser,auth_tcpuser3) dnl User authentication according to RFC 931.
AC_CHECK_LIB(socket,socket) dnl socket() et c on Solaris 2.
AC_CHECK_LIB(nsl,gethostbyname) dnl Low-level networking code on Solaris 2.
AC_CHECK_LIB(i,setlocale) dnl For setlocale() on Ultrix.
AC_CHECK_FUNCS(difftime getdtablesize sysconf strchr getcwd vfprintf)
AC_CHECK_FUNCS(setrlimit)
AC_REPLACE_FUNCS(memcpy strerror remove memset memchr setsid)
dnl
dnl I don't know how to test for buggy inet_ntoa functions
dnl programmatically, but the supplied substitute should always work,
dnl so we define BUGGY_INET_NTOA unconditionally.
AC_DEFINE(BUGGY_INET_NTOA)
dnl
dnl Unencryptet passwords are no longer supported.
AC_DEFINE(ENCRYPT_PASSWORDS)
dnl
dnl Once upon a time, the server shared some code with the tty-client.
dnl Because of that, you still have to define SERVER while compiling
dnl some of the files in this package.  Nowadays sharing is done by copying.
AC_DEFINE(SERVER)
dnl
AC_OUTPUT(Makefile
doc/Makefile
doc/man/Makefile
scripts/Makefile
src/Makefile
src/include/Makefile
src/include/server/Makefile
src/libraries/Makefile
src/libraries/libansi/Makefile
src/libraries/libcommon/Makefile
src/libraries/libisc-new/Makefile
src/libraries/libisc-new/src/Makefile
src/libraries/libmisc/Makefile
src/libraries/regex/Makefile
src/server/Makefile
run-support/Makefile)