configure.ac 18.9 KB
Newer Older
Niels Möller's avatar
Niels Möller committed
1
2
dnl -*- mode: shell-script; sh-indentation: 2; -*-

3
4
dnl Process this file with autoconf to produce a configure script.

5
AC_INIT([nettle], [2.5], [nettle-bugs@lists.lysator.liu.se])
6
AC_PREREQ(2.61)
7
8
9
10
AC_CONFIG_SRCDIR([arcfour.c])
# Needed to stop autoconf from looking for files in parent directories.
AC_CONFIG_AUX_DIR([.])

11
AC_CONFIG_HEADER([config.h])
12

13
LIBNETTLE_MAJOR=4
14
LIBNETTLE_MINOR=3
15

16
LIBHOGWEED_MAJOR=2
17
LIBHOGWEED_MINOR=1
18

19
20
AC_CANONICAL_HOST

21
22
23
24
25
26
# Command line options
AC_ARG_WITH(include-path,
  AC_HELP_STRING([--with-include-path], [A colon-separated list of directories to search for include files]),,
  [with_include_path=''])

if test x$with_include_path != x ; then
27
  CPPFLAGS="$CPPFLAGS -I`echo $with_include_path | sed 's/:/ -I/g'`"
28
29
30
31
32
33
34
fi

AC_ARG_WITH(lib-path,
  AC_HELP_STRING([--with-lib-path], [A colon-separated list of directories to search for libraries]),,
  [with_lib_path=''])

if test x$with_lib_path != x ; then
35
  LDFLAGS="$LDFLAGS -L`echo $with_lib_path | sed 's/:/ -L/g'`"
36
37
fi

38
39
40
41
AC_ARG_ENABLE(public-key,
  AC_HELP_STRING([--disable-public-key], [Disable public key algorithms]),,
  [enable_public_key=yes])

42
AC_ARG_ENABLE(assembler,
43
44
  AC_HELP_STRING([--disable-assembler],[Disable assembler code]),,
  [enable_assembler=yes])
45

46
AC_ARG_ENABLE(shared,
47
  AC_HELP_STRING([--enable-shared], [Build a shared library]),,
48
49
  [enable_shared=no])

50
51
52
53
54
AC_ARG_ENABLE(pic,
  AC_HELP_STRING([--disable-pic],
  [Do not try to compile library files as position independent code]),,
  [enable_pic=yes])

55
56
57
AC_ARG_ENABLE(openssl,
  AC_HELP_STRING([--disable-openssl], [Do not include openssl glue in the benchmark program]),,
  [enable_openssl=yes])
58
59
60
61
62

AC_ARG_ENABLE(gcov,
  AC_HELP_STRING([--enable-gcov], [Instrument for gcov (requires a modern gcc)]),,
  [enable_gcov=no])

63
64
65
66
67
LSH_RPATH_INIT([`echo $with_lib_path | sed 's/:/ /g'` \
    `echo $exec_prefix | sed "s@^NONE@$prefix/lib@g" | sed "s@^NONE@$ac_default_prefix/lib@g"` \
    /usr/local/lib /sw/local/lib /sw/lib \
    /usr/gnu/lib /opt/gnu/lib /sw/gnu/lib /usr/freeware/lib /usr/pkg/lib])

68
# Checks for programs.
Niels Möller's avatar
Niels Möller committed
69
AC_PROG_CC
70
71
72
73
74
75
76
77

# When $CC foo.c -o foo creates both foo and foo.exe, autoconf picks
# up the foo.exe and sets exeext to .exe. That is correct for cygwin,
# which has some kind of magic link from foo to foo.exe, but not for
# rntcl. A better check for the cygwin case would check if the
# contents of foo and foo.exe are equal; in the rntcl case, foo is a
# sh script, and foo.exe is a windows executable.

Niels Möller's avatar
Niels Möller committed
78
if test "x$CC" = xrntcl ; then
79
    AC_MSG_NOTICE([Compiling with rntcl; clearing EXEEXT and disabling assembler])
80
81
    ac_exeext=''
    ac_cv_exeext=''
Niels Möller's avatar
Niels Möller committed
82
    EXEEXT=''
83
    enable_assembler=no
84
85
fi

86
87
88
89
90
91
92
93
# Used by the testsuite only
AC_PROG_CXX

AC_LANG_PUSH(C++)
AC_TRY_COMPILE([],[return 0;],[CXX_TESTS='cxx-test$(EXEEXT)'], [CXX_TESTS=''])
AC_SUBST([CXX_TESTS])
AC_LANG_POP

Niels Möller's avatar
Niels Möller committed
94
AC_PROG_MAKE_SET
Niels Möller's avatar
Niels Möller committed
95
AC_PROG_RANLIB
96
AC_CHECK_TOOL(NM, nm, strings)
97
98
# Used only for the GNU-stack configure test.
AC_CHECK_TOOL(OBJDUMP, objdump, false)
Niels Möller's avatar
Niels Möller committed
99

100
if test "x$ac_cv_prog_cc_stdc" = xno ; then
101
  AC_ERROR([the C compiler doesn't handle ANSI-C]) #'
Niels Möller's avatar
Niels Möller committed
102
fi
103

104
105
AC_PROG_INSTALL

106
107
108
109
# According to the autoconf manual, needs install-sh from
# autoconf-2.60 or automake-1.10 to avoid races.
AC_PROG_MKDIR_P

110
111
LSH_DEPENDENCY_TRACKING

112
if test x$enable_dependency_tracking = xyes ; then
113
114
115
  # Since the makefiles use include to get the dependency files, we must
  # make sure that the files exist. We generate some more files than are
  # actually needed.
116

117
118
  AC_CONFIG_COMMANDS([dummy-dep-files],
  [(cd "$srcdir" && find . -name '*.c' -print) \
119
 | sed 's/\.c$//' | (while read f; do echo > "$f.o.d"; echo > "$f.po.d"; done)
120
])
121
fi
122

123
# Figure out ABI. Currently, configurable only by setting CFLAGS.
124
125
ABI=standard

126
case "$host_cpu" in
127
  [x86_64 | amd64])
128
    AC_TRY_COMPILE([
129
130
#if defined(__x86_64__) || defined(__arch64__)
#error 64-bit x86
131
132
#endif
    ], [], [
133
      ABI=32
134
    ], [
135
      ABI=64
136
    ])
137
    ;;
138
  *sparc*)
139
140
141
142
143
    AC_TRY_COMPILE([
#if defined(__sparcv9) || defined(__arch64__)
#error 64-bit sparc
#endif
    ], [], [
144
      ABI=32
145
    ], [
146
      ABI=64
147
    ])
148
    ;;
149
150
151
esac

if test "x$ABI" != xstandard ; then
152
  AC_MSG_NOTICE([Compiler uses $ABI-bit ABI. To change, set CC.])
153
154
155
156
157
158
159
160
161
  if test "$libdir" = '${exec_prefix}/lib' ; then
    # Try setting a better default
    case "$host_cpu:$host_os:$ABI" in
      *:solaris*:32|*:sunos*:32)
	libdir='${exec_prefix}/lib'
	;;
      *:solaris*:64|*:sunos*:64)
	libdir='${exec_prefix}/lib/64'
	;;
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
      # Linux conventions are a mess... According to the Linux File
      # Hierarchy Standard, all architectures except IA64 puts 32-bit
      # libraries in lib, and 64-bit in lib64. Some distributions,
      # e.g., Fedora and Gentoo, adhere to this standard, while at
      # least Debian has decided to put 64-bit libraries in lib and
      # 32-bit libraries in lib32.
      
      # We try to figure out the convention, except if we're cross
      # compiling. We use lib${ABI} if /usr/lib${ABI} exists and
      # appears to not be a symlink to a different name.
      *:linux*:32|*:linux*:64)
	if test "$cross_compiling" = yes ; then
          AC_MSG_WARN([Cross compiling for linux. Can't guess if libraries go in lib${ABI} or lib.]); dnl '
	else
	  # The dash builtin pwd tries to be "helpful" and remember
177
	  # symlink names. Use -P option, and hope it's portable enough.
178
	  test -d /usr/lib${ABI} \
179
	    && (cd /usr/lib${ABI} && pwd -P | grep >/dev/null "/lib${ABI}"'$') \
180
181
	    && libdir='${exec_prefix}/'"lib${ABI}"
	fi
182
183
184
185
186
187
188
189
190
191
192
	;;
      # On freebsd, it seems 32-bit libraries are in lib32,
      # and 64-bit in lib. Don't know about "kfreebsd", does
      # it follow the Linux fhs conventions?
      *:freebsd*:32)
	libdir='${exec_prefix}/lib32'
	;;
      *:freebsd*:64)
	libdir='${exec_prefix}/lib'
	;;
      *)
193
        AC_MSG_WARN([Don't know where to install $ABI-bit libraries on this system.]); dnl '
194
195
196
197

    esac
    AC_MSG_NOTICE([Libraries to be installed in $libdir.])
  fi
198
199
200
201
fi

# Select assembler code
asm_path=
202
203
204
if test "x$enable_assembler" = xyes ; then
  case "$host_cpu" in
    [i?86* | k[5-8]* | pentium* | athlon])
205
      asm_path=x86
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
      ;;
    [x86_64 | amd64])
      if test "$ABI" = 64 ; then
	asm_path=x86_64
      else
	asm_path=x86
      fi
      ;;
    *sparc*)
      if test "$ABI" = 64 ; then
	asm_path=sparc64
      else
	asm_path=sparc32
      fi
      ;;
    *)
      enable_assembler=no
      ;;
  esac
fi
226
# echo "enable_assembler: $enable_assembler, asm_path: $asm_path"
227

228
if test "x$enable_assembler" = xyes ; then
229
  if test -n "$asm_path"; then
Niels Möller's avatar
Niels Möller committed
230
    AC_MSG_NOTICE([Looking for assembler files in $asm_path/.])
231
    found=no
232
    for tmp_f in aes-encrypt-internal.asm aes-decrypt-internal.asm \
233
		 arcfour-crypt.asm camellia-crypt-internal.asm \
234
235
		 md5-compress.asm memxor.asm \
		 serpent-encrypt.asm serpent-decrypt.asm \
236
		 sha1-compress.asm machine.m4; do
237
238
#       echo "Looking for $srcdir/$asm_path/$tmp_f"
      if test -f "$srcdir/$asm_path/$tmp_f"; then
239
#        echo found
240
        found=yes
241
        AC_CONFIG_LINKS($tmp_f:$asm_path/$tmp_f)
242
243
244
245
246
247
248
249
250
      fi
    done
    if test "$found" = no; then
      enable_assembler=no
      AC_MSG_WARN([No assembler files found.])
    fi
  fi
fi

251
252
253
LSH_CCPIC

SHLIBCFLAGS="$CCPIC"
254

255
256
257
IF_DLL='#'
LIBNETTLE_FILE_SRC='$(LIBNETTLE_FORLINK)'
LIBHOGWEED_FILE_SRC='$(LIBHOGWEED_FORLINK)'
258
EMULATOR=''
259

260
case "$host_os" in
Martin Storsjö's avatar
Martin Storsjö committed
261
  mingw32*|cygwin*)
262
263
264
265
    # The actual DLLs, e.g. libnettle-$major-$minor.dll, are normally
    # installed into the bin dir (or more exactly $libdir/../bin, for
    # automake), while libnettle.dll.a, which is a stub file for
    # linking to the DLL, is installed into the lib dir.
Martin Storsjö's avatar
Martin Storsjö committed
266
267
268
269
270
271
272
273
274
275
    case "$host_os" in
      mingw32*)
        LIBNETTLE_FORLINK='libnettle-$(LIBNETTLE_MAJOR)-$(LIBNETTLE_MINOR).dll'
        LIBHOGWEED_FORLINK='libhogweed-$(LIBHOGWEED_MAJOR)-$(LIBHOGWEED_MINOR).dll'
        ;;
      cygwin*)
        LIBNETTLE_FORLINK='cygnettle-$(LIBNETTLE_MAJOR)-$(LIBNETTLE_MINOR).dll'
        LIBHOGWEED_FORLINK='cyghogweed-$(LIBHOGWEED_MAJOR)-$(LIBHOGWEED_MINOR).dll'
        ;;
    esac
276
277
278
279
280
281
282
283
284
    # FIXME: Support native compilation using mingw on windows.
    case "$ABI" in
    64)
        EMULATOR=wine64
        ;;
    *)
        EMULATOR=wine
        ;;
    esac
285
286
    LIBNETTLE_SONAME=''
    LIBNETTLE_FILE='libnettle.dll.a'
287
    LIBNETTLE_FILE_SRC='$(LIBNETTLE_FILE)'
288
    LIBNETTLE_LINK='$(CC) $(LDFLAGS) -shared -Wl,--out-implib=$(LIBNETTLE_FILE) -Wl,--export-all-symbols -Wl,--enable-auto-import -Wl,--whole-archive'
289
290
291
    LIBNETTLE_LIBS='-Wl,--no-whole-archive $(LIBS)'

    LIBHOGWEED_SONAME=''
292
    LIBHOGWEED_FILE='libhogweed.dll.a'
293
    LIBHOGWEED_FILE_SRC='$(LIBHOGWEED_FILE)'
294
    LIBHOGWEED_LINK='$(CC) $(LDFLAGS) -shared -Wl,--out-implib=$(LIBHOGWEED_FILE) -Wl,--export-all-symbols -Wl,--enable-auto-import -Wl,--whole-archive'
295
    LIBHOGWEED_LIBS='-Wl,--no-whole-archive $(LIBS) libnettle.dll.a'
296
    IF_DLL=''
297
    ;;
Grant Robinson's avatar
Grant Robinson committed
298
  darwin*)
299
    LIBNETTLE_FORLINK=libnettle.dylib
300
301
302
    LIBNETTLE_SONAME='libnettle.$(LIBNETTLE_MAJOR).dylib'
    LIBNETTLE_FILE='libnettle.$(LIBNETTLE_MAJOR).$(LIBNETTLE_MINOR).dylib'
    LIBNETTLE_LINK='$(CC) -dynamiclib $(LDFLAGS) -install_name ${libdir}/$(LIBNETTLE_SONAME) -compatibility_version $(LIBNETTLE_MAJOR) -current_version $(LIBNETTLE_MAJOR).$(LIBNETTLE_MINOR)'
303
304
    LIBNETTLE_LIBS=''

305
    LIBHOGWEED_FORLINK=libhogweed.dylib
306
307
308
    LIBHOGWEED_SONAME='libhogweed.$(LIBHOGWEED_MAJOR).dylib'
    LIBHOGWEED_FILE='libhogweed.$(LIBHOGWEED_MAJOR).$(LIBHOGWEED_MINOR).dylib'
    LIBHOGWEED_LINK='$(CC) -dynamiclib -L. $(LDFLAGS) -install_name ${libdir}/$(LIBHOGWEED_SONAME) -compatibility_version $(LIBHOGWEED_MAJOR) -current_version $(LIBHOGWEED_MAJOR).$(LIBHOGWEED_MINOR)'
309
    LIBHOGWEED_LIBS='-lnettle -lgmp'
Grant Robinson's avatar
Grant Robinson committed
310
    ;;
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
  solaris*)
    # Sun's ld uses -h to set the soname, and this option is passed
    # through by both Sun's compiler and gcc. Might not work with GNU
    # ld, but it's unusual to use GNU ld on Solaris.
    LIBNETTLE_FORLINK=libnettle.so
    LIBNETTLE_SONAME='$(LIBNETTLE_FORLINK).$(LIBNETTLE_MAJOR)'
    LIBNETTLE_FILE='$(LIBNETTLE_SONAME).$(LIBNETTLE_MINOR)'
    LIBNETTLE_LINK='$(CC) $(LDFLAGS) -G -h $(LIBNETTLE_SONAME)'
    LIBNETTLE_LIBS=''

    LIBHOGWEED_FORLINK=libhogweed.so
    LIBHOGWEED_SONAME='$(LIBHOGWEED_FORLINK).$(LIBHOGWEED_MAJOR)'
    LIBHOGWEED_FILE='$(LIBHOGWEED_SONAME).$(LIBHOGWEED_MINOR)'
    LIBHOGWEED_LINK='$(CC) $(LDFLAGS) -L. -G -h $(LIBHOGWEED_SONAME)'
    LIBHOGWEED_LIBS='-lnettle -lgmp'
    ;;
327
  *)
328
329
330
331
332
333
    LIBNETTLE_FORLINK=libnettle.so
    LIBNETTLE_SONAME='$(LIBNETTLE_FORLINK).$(LIBNETTLE_MAJOR)'
    LIBNETTLE_FILE='$(LIBNETTLE_SONAME).$(LIBNETTLE_MINOR)'
    LIBNETTLE_LINK='$(CC) $(LDFLAGS) -shared -Wl,-soname=$(LIBNETTLE_SONAME)'
    LIBNETTLE_LIBS=''

334
    LIBHOGWEED_FORLINK=libhogweed.so
335
336
    LIBHOGWEED_SONAME='$(LIBHOGWEED_FORLINK).$(LIBHOGWEED_MAJOR)'
    LIBHOGWEED_FILE='$(LIBHOGWEED_SONAME).$(LIBHOGWEED_MINOR)'
337
338
339
340
341
342
343
    LIBHOGWEED_LINK='$(CC) $(LDFLAGS) -L. -shared -Wl,-soname=$(LIBHOGWEED_SONAME)'
    # Requested by debian, to make linking with only -lhogweed work
    # (does not work in general, e.g., with static linking all of
    # -lhogweed -lgmp -lnettle are still required). Also makes dlopen
    # of libhogweed.so work, without having to use RTLD_GLOBAL.
    # Depends on -L. above, to locate nettle.so.
    LIBHOGWEED_LIBS='-lnettle -lgmp'
344
345
    ;;
esac
346

347
348
349
350
if test "x$enable_pic" = xyes; then
  CCPIC_MAYBE="$CCPIC"
else
  CCPIC_MAYBE=''
351
fi
352
AC_SUBST([CCPIC_MAYBE])
353

354
ASM_SYMBOL_PREFIX=''
355
ASM_ELF_STYLE='no'
356
ASM_TYPE_FUNCTION=''
357
ASM_MARK_NOEXEC_STACK=''
358
ASM_ALIGN_LOG=''
359
360
361
362
363
364
365
366

if test x$enable_assembler = xyes ; then
  AC_CACHE_CHECK([if globals are prefixed by underscore],
  nettle_cv_asm_underscore,
  [ # Default is no underscore
    nettle_cv_asm_underscore=no
    AC_COMPILE_IFELSE(
      [int a_global_symbol;],
367
      [ $NM conftest.$OBJEXT >conftest.out
368
369
370
371
372
373
374
375
        if grep _a_global_symbol conftest.out >/dev/null ; then
          nettle_cv_asm_underscore=yes
        elif grep a_global_symbol conftest.out >/dev/null ; then
          nettle_cv_asm_underscore=no
        else
          AC_MSG_WARN([nm doesn't list a_global_symbol at all])
	fi],
      [AC_MSG_WARN([test program with a single global could not be compiled!?])])])
376
  if test x$nettle_cv_asm_underscore = xyes ; then
377
    ASM_SYMBOL_PREFIX='_'
378
  fi
379
380
381
382
383
384
385
386
387
388
389
390

  AC_CACHE_CHECK([if we should use a .note.GNU-stack section],
  nettle_cv_asm_gnu_stack,
  [ # Default
    nettle_cv_asm_gnu_stack=no

    cat >conftest.c <<EOF
int foo() { return 0; }
EOF
    nettle_compile="$CC $CFLAGS $CPPFLAGS -c conftest.c >conftest.out 2>&1"
    if AC_TRY_EVAL(nettle_compile); then
      cat conftest.out >&AC_FD_CC
391
      $OBJDUMP -x conftest.o | grep '\.note\.GNU-stack' > /dev/null \
392
393
394
395
396
397
398
399
400
401
402
      && nettle_cv_asm_gnu_stack=yes
    else
      cat conftest.out >&AC_FD_CC
      echo "configure: failed program was:" >&AC_FD_CC
      cat conftest.s >&AC_FD_CC
    fi
    rm -f conftest.*])
  if test x$nettle_cv_asm_gnu_stack = xyes ; then
    ASM_MARK_NOEXEC_STACK='.section .note.GNU-stack,"",@progbits'
  fi

403
404
405
  AC_CACHE_CHECK([for ELF-style .type,%function pseudo-ops],
    [nettle_cv_asm_type_percent_function],
    [GMP_TRY_ASSEMBLE([
406
407
.text
.globl foo
408
.type foo,%function
409
410
411
412
foo:
.Lend:

.size foo, .Lend - foo
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
],
       [nettle_cv_asm_type_percent_function=yes],
       [nettle_cv_asm_type_percent_function=no])])

dnl Needs double quote for the # character
  AC_CACHE_CHECK([[for ELF-style .type,#function pseudo-ops]],
    [nettle_cv_asm_type_hash_function],
    [GMP_TRY_ASSEMBLE([
.text
.globl foo
.type foo,#function
foo:
.Lend:

.size foo, .Lend - foo
],
       [nettle_cv_asm_type_hash_function=yes],
       [nettle_cv_asm_type_hash_function=no])])

  if test x$nettle_cv_asm_type_percent_function = xyes ; then
433
    ASM_ELF_STYLE='yes'
434
435
436
437
438
439
    ASM_TYPE_FUNCTION='%function'
  else
    if test x$nettle_cv_asm_type_hash_function = xyes ; then
      ASM_ELF_STYLE='yes'
      ASM_TYPE_FUNCTION='#function'
    fi
440
  fi
441
442
443
444
445
446
447
448
449
450
  AC_CACHE_CHECK([if .align assembly directive is logarithmic],
    [nettle_cv_asm_align_log],
    [GMP_TRY_ASSEMBLE([
.align 3
],
       [nettle_cv_asm_align_log=yes],
       [nettle_cv_asm_align_log=no])])
  if test x$nettle_cv_asm_align_log = xyes ; then
    ASM_ALIGN_LOG='yes'
  fi
451
452
453
fi

AC_SUBST(ASM_SYMBOL_PREFIX)
454
AC_SUBST(ASM_ELF_STYLE)
455
AC_SUBST(ASM_TYPE_FUNCTION)
456
AC_SUBST(ASM_MARK_NOEXEC_STACK)
457
AC_SUBST(ASM_ALIGN_LOG)
458
AC_SUBST(EMULATOR)
459

460
AC_SUBST(SHLIBCFLAGS)
461
462
463
464
465
466

AC_SUBST(LIBNETTLE_MAJOR)
AC_SUBST(LIBNETTLE_MINOR)
AC_SUBST(LIBNETTLE_FORLINK)
AC_SUBST(LIBNETTLE_SONAME)
AC_SUBST(LIBNETTLE_FILE)
467
AC_SUBST(LIBNETTLE_FILE_SRC)
468
469
470
AC_SUBST(LIBNETTLE_LINK)
AC_SUBST(LIBNETTLE_LIBS)

Niels Möller's avatar
Niels Möller committed
471
472
473
474
475
AC_SUBST(LIBHOGWEED_MAJOR)
AC_SUBST(LIBHOGWEED_MINOR)
AC_SUBST(LIBHOGWEED_FORLINK)
AC_SUBST(LIBHOGWEED_SONAME)
AC_SUBST(LIBHOGWEED_FILE)
476
AC_SUBST(LIBHOGWEED_FILE_SRC)
Niels Möller's avatar
Niels Möller committed
477
478
AC_SUBST(LIBHOGWEED_LINK)
AC_SUBST(LIBHOGWEED_LIBS)
Niels Möller's avatar
Niels Möller committed
479

Niels Möller's avatar
Niels Möller committed
480
AC_PATH_PROG(M4, m4, m4)
481

482
483
484
485
if test "x$enable_gcov" = "xyes"; then
  CFLAGS="$CFLAGS -ftest-coverage -fprofile-arcs"
fi

486
# Checks for typedefs, structures, and compiler characteristics.
Niels Möller's avatar
Niels Möller committed
487
AC_C_CONST
Niels Möller's avatar
Niels Möller committed
488
489
490
491
AC_C_INLINE
AC_TYPE_UID_T
AC_TYPE_SIZE_T
AC_HEADER_TIME
Niels Möller's avatar
Niels Möller committed
492
AC_CHECK_SIZEOF(long)
493
494
495
496
AC_CHECK_ALIGNOF(uint64_t)

ALIGNOF_UINT64_T="$ac_cv_alignof_uint64_t"
AC_SUBST(ALIGNOF_UINT64_T)
Niels Möller's avatar
Niels Möller committed
497

Niels Möller's avatar
Niels Möller committed
498
AC_CHECK_HEADERS([openssl/blowfish.h openssl/des.h openssl/cast.h openssl/aes.h],,
499
500
501
[enable_openssl=no
 break])

Niels Möller's avatar
Niels Möller committed
502
LSH_FUNC_ALLOCA
Niels Möller's avatar
Niels Möller committed
503
LSH_FUNC_STRERROR
Niels Möller's avatar
Niels Möller committed
504

Niels Möller's avatar
Niels Möller committed
505
# Needed by the supplied memcmp.c
Niels Möller's avatar
Niels Möller committed
506
AC_C_BIGENDIAN
Niels Möller's avatar
Niels Möller committed
507
508
AC_REPLACE_FUNCS(memxor)

Niels Möller's avatar
Niels Möller committed
509
LSH_GCC_ATTRIBUTES
Niels Möller's avatar
Niels Möller committed
510

511
512
# According to Simon Josefsson, looking for uint32_t and friends in
# sys/types.h is needed on some systems, in particular cygwin.
513
AX_CREATE_STDINT_H([nettle-stdint.h], [sys/types.h])
514

Niels Möller's avatar
Niels Möller committed
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
# Check for file locking. We (AC_PROG_CC?) have already checked for
# sys/types.h and unistd.h.
AC_CACHE_CHECK([for fcntl file locking],
		nettle_cv_fcntl_locking,
[AC_TRY_COMPILE([
#if HAVE_SYS_TYPES_H
# include <sys/types.h>
#endif
#if HAVE_UNISTD_H
# include <unistd.h>
#endif
#include <fcntl.h>
],[
int op = F_SETLKW;
struct flock fl;
],
nettle_cv_fcntl_locking=yes,
nettle_cv_fcntl_locking=no)])

AH_TEMPLATE([HAVE_FCNTL_LOCKING], [Define if fcntl file locking is available])
if test "x$nettle_cv_fcntl_locking" = "xyes" ; then
  AC_DEFINE(HAVE_FCNTL_LOCKING)
fi

539
540
541
# Checks for libraries
AC_CHECK_LIB(gmp, __gmpz_getlimbn,,
    [AC_MSG_WARN(
Niels Möller's avatar
Niels Möller committed
542
[GNU MP not found, or not 3.1 or up, see http://gmplib.org/.
543
544
545
Support for public key algorithms will be unavailable.])]
    enable_public_key=no)

Niels Möller's avatar
Niels Möller committed
546
547
548
549
550
551
# Add -R flags needed to run programs linked with gmp
LSH_RPATH_FIX

AH_TEMPLATE([HAVE_MPZ_POWM_SEC], [Define if mpz_powm_sec is available (appeared in GMP-5)])
AC_CHECK_FUNC(__gmpz_powm_sec, [AC_DEFINE(HAVE_MPZ_POWM_SEC)])

552
553
AH_TEMPLATE([WITH_HOGWEED], [Defined if public key features are enabled])

554
if test "x$enable_public_key" = xyes ; then
555
556
557
558
559
560
561
562
  AC_DEFINE(WITH_HOGWEED)
  IF_HOGWEED=''
else
  IF_HOGWEED='#'
fi

if test "x$enable_shared" = xyes ; then
  IF_SHARED=''
563
else
564
  IF_SHARED='#'
565
566
fi

567
568
AC_SUBST(IF_HOGWEED)
AC_SUBST(IF_SHARED)
569
AC_SUBST(IF_DLL)
570

571
572
OPENSSL_LIBFLAGS=''

573
# Check for openssl's libcrypto (used only for benchmarking)
574
575
576
577
578
579
580
581
582
583
584
585
if test x$enable_openssl = xyes ; then
  AC_CHECK_LIB(crypto, BF_ecb_encrypt,
    [OPENSSL_LIBFLAGS='-lcrypto'],
    [enable_openssl=no])
fi

AH_TEMPLATE([WITH_OPENSSL],
	    [Define if you have openssl's libcrypto (used for benchmarking)])

if test x$enable_openssl = xyes ; then
  AC_DEFINE(WITH_OPENSSL)
fi
586
587

AC_SUBST(OPENSSL_LIBFLAGS)
588

589
590
591
592
593
594
# Choose strategy for Camellia round
AH_BOTTOM(
[/* Needs include of <limits.h> before use. */
#define HAVE_NATIVE_64_BIT (SIZEOF_LONG * CHAR_BIT >= 64)
])

595
596
597
598
599
600
601
602
603
604
605
606
607
# clock_gettime is in librt on *-*-osf5.1 and on glibc, so add -lrt to
# BENCH_LIBS if needed. On linux (tested on x86_32, 2.6.26),
# clock_getres reports ns accuracy, while in a quick test on osf
# clock_getres said only 1 millisecond.

old_LIBS="$LIBS"
AC_SEARCH_LIBS(clock_gettime, rt, [
  AC_DEFINE([HAVE_CLOCK_GETTIME],1,[Define to 1 if you have the `clock_gettime' function])])
BENCH_LIBS="$LIBS"
LIBS="$old_LIBS"

AC_SUBST(BENCH_LIBS)

Niels Möller's avatar
Niels Möller committed
608
609
# Set these flags *last*, or else the test programs won't compile
if test x$GCC = xyes ; then
610
  # Using -ggdb3 makes (some versions of) Redhat's gcc-2.96 dump core
611
  if $CC --version | grep '^2\.96$' 1>/dev/null 2>&1; then
612
613
614
615
    true
  else
    CFLAGS="$CFLAGS -ggdb3"
  fi
616
  # FIXME: It would be better to actually test if this option works and/or is needed.
Niels Möller's avatar
Niels Möller committed
617
  # Or perhaps use -funsigned-char.
618
  if $CC --version | grep 'gcc.* 4\.' 1>/dev/null 2>&1; then
619
620
    CFLAGS="$CFLAGS -Wno-pointer-sign"
  fi
621
622
623
  CFLAGS="$CFLAGS -Wall -W \
  -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes \
  -Wpointer-arith -Wbad-function-cast -Wnested-externs"
Niels Möller's avatar
Niels Möller committed
624
625
626

# Don't enable -Wcast-align as it results in tons of warnings in the
# DES code. And when using stdio.
627
628
# Don't enable -Waggregate-return, as that causes warnings for glibc
# inttypes.h.
Niels Möller's avatar
Niels Möller committed
629
fi
Niels Möller's avatar
Niels Möller committed
630

631
632
AC_CONFIG_FILES([config.make config.m4 Makefile])
AC_CONFIG_FILES([tools/Makefile testsuite/Makefile examples/Makefile])
633
AC_CONFIG_FILES([nettle.pc hogweed.pc])
634
635

AC_OUTPUT
636

637
638
639
640
641
642
643
644
645
646
647
648
AC_MSG_NOTICE([summary of build options:

  Version:           ${PACKAGE_STRING}
  Host type:         ${host}
  ABI:               ${ABI}
  Assembly files:    ${asm_path:-none}
  Install prefix:    ${prefix}
  Library directory: ${libdir}
  Compiler:          ${CC}
  Shared libraries:  ${enable_shared}
  Public key crypto: ${enable_public_key}
])