lyskom-rest.el

;;;;;
;;;;; $Id$
;;;;; Copyright (C) 1991, 1996  Lysator Academic Computer Association.
;;;;;
;;;;; This file is part of the LysKOM server.
;;;;; 
;;;;; LysKOM is free software; you can redistribute it and/or modify it
;;;;; under the terms of the GNU General Public License as published by 
;;;;; the Free Software Foundation; either version 2, or (at your option) 
;;;;; any later version.
;;;;; 
;;;;; LysKOM is distributed in the hope that it will be useful, but WITHOUT
;;;;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
;;;;; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
;;;;; for more details.
;;;;; 
;;;;; You should have received a copy of the GNU General Public License
;;;;; along with LysKOM; see the file COPYING.  If not, write to
;;;;; Lysator, c/o ISY, Linkoping University, S-581 83 Linkoping, SWEDEN,
;;;;; or the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, 
;;;;; MA 02139, USA.
;;;;;
;;;;; Please mail bug reports to bug-lyskom@lysator.liu.se. 
;;;;;
;;;; ================================================================
;;;; ================================================================
;;;;
;;;; File: lyskom-rest.el
;;;;
;;;; This is the rest of what was once the entire source code of the
;;;; client. Now most of the source resides in other files. Eventually
;;;; the functions in here will be distributed out to other files.
;;;; Below follows the original header of the LysKOM elisp client:
;;;;
;;;; ================================================================
;;;;
;;;; Simple LysKOM elisp client.
;;;;
;;;; Originally written by Per Cederqvist.
;;;;
;;;; Heavily hacked by:
;;;;    Thomas Bellman
;;;;    Linus Tolke
;;;;    Inge Wallin
;;;;   and others.
;;;;
;;;; Some ideas stolen from lpmud.el written by Lars Willf|r and Thomas Bellman
;;;;
;;;; Conventions:
;;;;
;;;;    All functions, variables etc follow one of these conventions:
;;;;		lyskom-		general functions.
;;;;		cache-		cache-routines.
;;;;		initiate-	call a service. (Might look up in cache)
;;;;		kom-		user kommands.
;;;;		lyskom-parse-	parse (part of) a reply from the server.
;;;;				these are found in parse.el
;;;;		lyskom-edit-	Things related to the editing of texts.
;;;;		{lyskom,kom}-edit-options-
;;;;				things related to editing options
;;;;				(found in flags.el)
;;;;		{lyskom,kom}-prioritize-
;;;;				things related to the prioritize
;;;;				buffer. The file is prioritize.el
;;;;		{lyskom,kom}-{completing-read,completing,complete}-
;;;;				things related to
;;;;				lyskom-completing-read. Found in
;;;;				completing-read.el 
;;;;		lyskom-*-hook   hooks.
;;;;
;;;;    Three plus-signs (+++) in the code marks a place where more
;;;;    work is needed.
;;;;

(setq lyskom-clientversion-long 
      (concat lyskom-clientversion-long
	      "$Id$\n"))


;;;; ================================================================
;;;;                             New errors.


(put 'lyskom-protocol-error 'error-conditions
     '(error lyskom-error lyskom-protocol-error))
(put 'lyskom-protocol-error 'error-message
     "LysKOM protocol error:")

(put 'lyskom-internal-error 'error-conditions
     '(error lyskom-error lyskom-internal-error))
(put 'lyskom-internal-error 'error-message
     "Internal LysKOM error.")

(put 'lyskom-format-error 'error-conditions
     '(error lyskom-error lyskom-format-error))
(put 'lyskom-internal-error 'error-message
     "Internal LysKOM format error.")


;;; ================================================================
;;;             Global variables
;;;

(defvar lyskom-unread-mode-line nil)

;;; ================================================================
;;;             Error reporting from a number of commands.
;;;

;;; Author: Inge Wallin



(defun lyskom-get-error-text (errno)
  "Get a string which is the error ERRNO in plain text."
  (let ((pair (assoc errno lyskom-error-texts)))
    (if pair 
	(cdr pair)
      (lyskom-format 'error-not-found errno))))


(defun lyskom-handle-command-answer (answer)
  "Handles a void return from call to the server."
  (lyskom-report-command-answer answer)
  (lyskom-end-of-command))


(defun lyskom-report-command-answer (answer)
  "Handles a void return from call to the server."
  (if answer 
      (lyskom-insert-string 'done)
    (lyskom-insert-string 'nope)
    (lyskom-format-insert 'error-code
			  (lyskom-get-error-text lyskom-errno)
			  lyskom-errno)))


;;; ----------------------------------------------------------------
;;; Author: Aronsson

(defun lyskom-tell-string (key)
  "Retrieve the phrase indexed by the key from the kom-tell-phrases
assoc list."
  (car (cdr (assoc key kom-tell-phrases))))


(defun lyskom-tell-internat (key)
  "Same as lyskom-tell-server, but use a key to a list of phrases."
  ;; The server at Lysator produces a lot of network traffic. The
  ;; solution should to be less verbose. This is very interesting
  ;; anymore, anyway.
  (lyskom-tell-server (lyskom-tell-string key)))


;;;; ================================================================
;;;; Aronsson was here 5 MAY 1991
					; kom-dict-*
(defconst kom-dict
  (append
   '(
     (kom-dict-vfsh		"VFSH") ; sample assoc entry
     )
   kom-tell-phrases			; Really?
   lyskom-commands)			; Really?

  "These texts are used all over the client. They were collected into
one huge assoc list to facilitate internationalization and personal
profiling. Users are encouraged to change this dictionary for fun.

Related variables are kom-tell-phrases and lyskom-commands.")

(defun lyskom-dict-string (key)
  "Retrieve the string indexed by the key from the kom-dict assoc list."
  (car (cdr (assoc key kom-dict))))


;;;; ================================================================
;;;;                User-level commands and functions.


(defun lyskom-command-name (command)
  "Get the command name for the command COMMAND"
  (car (cdr (assoc command 
		   (if kom-emacs-knows-iso-8859-1
		       lyskom-commands
		     lyskom-swascii-commands)))))


(defun lyskom-ok-command (alternative administrator)
  "Returns non-nil if it is ok to do such a command right now."
  (if administrator
      (not (memq (car (cdr alternative)) lyskom-admin-removed-commands))
    (not (memq (car (cdr alternative)) lyskom-noadmin-removed-commands))))


(defun kom-extended-command ()
  "Read a LysKOM function name and call the function."
  (interactive)
  (let* ((completion-ignore-case t)
	 (alternatives (mapcar (function reverse)
			       (if kom-emacs-knows-iso-8859-1
				   lyskom-commands
				 lyskom-swascii-commands)))
	 (name (completing-read (lyskom-get-string 'extended-command)
				alternatives 
				;; lyskom-is-administrator is buffer-local and
				;; must be evalled before the call to 
				;; completing-read
				;; Yes, this is not beautiful
				(list 'lambda '(alternative)
				      (list 'lyskom-ok-command 'alternative
					    lyskom-is-administrator))
				t nil))
	 (fnc (reverse-assoc (car (all-completions name alternatives)) 
			     (if kom-emacs-knows-iso-8859-1
				 lyskom-commands
			       lyskom-swascii-commands))))
    (cond
     (fnc (call-interactively (car fnc)))
     (t (kom-next-command)))))


;;; Resume operation after a crash.

(defun kom-recover (&optional refetch)
  "Try to recover from an error.
If the optional argument REFETCH is non-nil, `lyskom-refetch' is called."
  (interactive "p")
  (lyskom-init-parse lyskom-buffer)
  (setq lyskom-call-data nil)
  (setq lyskom-pending-calls nil)
  (setq lyskom-output-queue (lyskom-queue-create))
  (setq lyskom-number-of-pending-calls 0)
  (setq lyskom-is-parsing nil)
  (if refetch (lyskom-refetch))
  (lyskom-tell-internat 'kom-tell-recover)
  (lyskom-end-of-command))


;;; ================================================================
;;;                      Run default command.


;;; Author: Tommy Persson

(defun kom-page-next-command ()
  "Scroll the bottom to the top and run the next command if it should be run"
  (interactive)
  (if (pos-visible-in-window-p (point-max))
      (progn
	(recenter 0)
	(lyskom-next-command))
    (recenter 0)
    (move-to-window-line -1)
    (lyskom-set-last-viewed)))


;;; Author: Lars Willf|r

(defun kom-next-command ()
  "Run next command or scroll one page."
  (interactive)
  (if (pos-visible-in-window-p (point-max))
      (lyskom-next-command)
    (move-to-window-line -1)
    (lyskom-set-last-viewed)
    (lyskom-scroll)))

  
(defun kom-line-next-command ()
  "Run next command or scroll one line."
  (interactive)
  (if (pos-visible-in-window-p (point-max))
      (lyskom-next-command)
    (move-to-window-line 1)
    (lyskom-set-last-viewed)
    (lyskom-scroll)))


;;; Author: Per Cederqvist

(defun lyskom-next-command ()
  "Run next command."
  (let ((lyskom-doing-default-command t))
    (cond
     ((eq lyskom-command-to-do 'next-pri-text)
      (lyskom-view-priority-text))
     ((eq lyskom-command-to-do 'next-text)
      (kom-view-next-text))
     ((eq lyskom-command-to-do 'next-conf)
      (kom-go-to-next-conf))
     ((eq lyskom-command-to-do 'next-pri-conf)
      (lyskom-go-to-pri-conf))
     ((eq lyskom-command-to-do 'when-done)
      (let ((command (lyskom-what-to-do-when-done)))
	(cond
	 ((stringp command)
	  (execute-kbd-macro command))
	 (t (call-interactively command)))))
     ((eq lyskom-command-to-do 'unknown)
      (lyskom-insert
       (lyskom-get-string 'wait-for-server)))
     (t (signal 'lyskom-internal-error '(kom-next-command))))))


;;; ================================================================
;;;                              View text.


(defun kom-initial-digit-view ()
  (interactive)
  (setq unread-command-events (cons last-command-event
                                    unread-command-events))
  (call-interactively 'kom-view nil))


(defun kom-view (text-no)
  "View text number TEXT-NO."
  (interactive "P")
  (unwind-protect
      (progn
	(let ((kom-page-before-command nil))
	  (lyskom-start-of-command 'kom-view)
	  (lyskom-tell-internat 'kom-tell-review)
	  )
	(if (setq text-no (cond ((null text-no) nil)
				((listp text-no) (car text-no))
				(t text-no)))
	    nil
	  (setq text-no (lyskom-read-number (lyskom-get-string 'review-text-q)
					    lyskom-current-text)))
	(if (or (not (listp kom-page-before-command))
		(memq 'kom-view kom-page-before-command))
	    (recenter 0))
	(lyskom-tell-internat 'kom-tell-review)
	(lyskom-format-insert 'review-text-no text-no)
	(lyskom-view-text text-no))
    (lyskom-end-of-command)))


;;;; ================================================================
;;;;                         View next text.


(defun kom-view-next-new-text ()
  "Display next new text (putting all review constructs at the end of this conf)."
  (interactive)
  (let ((len (read-list-length lyskom-reading-list))
	(finished nil))
    (while (and (not finished)
		(> len 1))
      (let ((type (read-info->type (read-list->first lyskom-reading-list))))
	(cond 
	 ((or (eq type 'REVIEW)
	      (eq type 'REVIEW-TREE)
	      (eq type 'REVIEW-MARK))
	  (read-list-rotate lyskom-reading-list))
	 ((or (eq type 'COMM-IN)
	      (eq type 'FOOTN-IN))
	  (set-read-list-del-first lyskom-reading-list))
	 (t 
	  (setq finished t))))
      (-- len)))
  (kom-view-next-text))


;;; Modified to handle filters

(def-kom-command kom-view-next-text ()
  "Display next text (from lyskom-reading-list)."
  (interactive)
  (lyskom-tell-internat 'kom-tell-read)
  (let ((action 'next-text))
    (while (eq action 'next-text)
      (if (read-list-isempty lyskom-reading-list)
	  (progn
	    (if (/= 0 lyskom-current-conf)
		(lyskom-insert-string 'completely-read-conf)
	      (lyskom-insert-string 'not-in-any-conf))
	    (setq action nil))
	      
	(progn
	  (let* ((tri (read-list->first lyskom-reading-list))
		 (text-no (car (cdr (read-info->text-list tri))))
		 (type (read-info->type tri))
		 (priority (read-info->priority
			    (read-list->first lyskom-reading-list)))
		 (is-review-tree (eq type 'REVIEW-TREE))
		 (is-review (or (eq type 'REVIEW)
				(eq type 'REVIEW-MARK)
				is-review-tree))
		 (mark-as-read (not is-review)))
	    (if is-review
		(delq text-no 
		      (read-info->text-list tri))) ;First entry only
	    (setq action
		  (lyskom-view-text text-no mark-as-read 
				    (and kom-read-depth-first
					 (not is-review))
				    (read-info->conf-stat
				     (read-list->first
				      lyskom-reading-list))
				    priority
				    is-review-tree
				    (not is-review)))
	    (if mark-as-read
		(lyskom-is-read text-no)
	      (read-list-delete-text nil lyskom-reading-list)
	      (read-list-delete-text nil lyskom-to-do-list))))))))
  

;;; Modified to handle filters

;; This is horribly ugly. It acts like a user command, but it isn't.
(defun lyskom-view-priority-text ()
  "Display the first text from the next conference on the lyskom-to-do-list."
  (lyskom-start-of-command 'kom-view-next-text)
  (unwind-protect
      (progn
	(lyskom-tell-internat 'kom-tell-read)
	(let* ((tri (read-list->first lyskom-to-do-list))
	       (priority (read-info->priority
			  (read-list->first lyskom-reading-list)))
	       (text-no (car (text-list->texts (read-info->text-list tri)))))
	  (lyskom-is-read text-no)
	  (lyskom-view-text text-no t nil (read-info->conf-stat tri) 
			    priority nil t))
	(lyskom-wait-queue 'main))
    (lyskom-end-of-command)))


(defun lyskom-is-read (text-no)
  "Remove TEXT-NO from the list of texts to read.
Deletes TEXT-NO from lyskom-reading-list and lyskom-to-do-list.
Adds info in lyskom-membership.

This function only modifies the internal state of the client. It does
not mark the text as read in the server. That function is performed by
lyskom-mark-as-read."
  (read-list-delete-text text-no lyskom-reading-list)
  (read-list-delete-text text-no lyskom-to-do-list)
  (initiate-get-text-stat 'main 'lyskom-is-read-handler text-no)
  (setq lyskom-normally-read-texts (cons text-no lyskom-normally-read-texts)))


(defun lyskom-is-read-handler (text-stat)
  "Update lyskom-membership for all recipients to TEXT-STAT."
  (lyskom-traverse
      misc (text-stat->misc-info-list text-stat)
    (if (or (eq 'RECPT (misc-info->type misc))
	    (eq 'CC-RECPT (misc-info->type misc)))
	(let ((membership (lyskom-member-p (misc-info->recipient-no misc))))
	  (if membership
	      (set-membership->read-texts
	       membership
	       (vconcat (vector (misc-info->local-no misc))
			(membership->read-texts membership))))))))


;;; ================================================================
;;;                        Go to next conf.


(def-kom-command kom-go-to-next-conf ()
  "Go to next conf.
Take first conf from lyskom-to-do-list and copy it to lyskom-reading-list.
Tell server what the user is doing. If the user is reading a conf it is
moved last on lyskom-to-do-list, with priority 0."
  (interactive)
  (lyskom-maybe-move-unread t)
  (lyskom-go-to-next-conf))


(defun lyskom-go-to-pri-conf ()
  "Go to the conf with higher priority.
This differs from kom-go-to-next-conf only in the place where the yet unread 
in the current conf is placed."
  (lyskom-start-of-command 'kom-go-to-next-conf)
  (lyskom-maybe-move-unread nil)
  (lyskom-go-to-next-conf)
  (lyskom-end-of-command))


(defun lyskom-go-to-next-conf ()
  "Actually go to the next conference on the lyskom-to-do-list"
  ;; Copy first element on lyskom-to-do-list to lyskom-reading-list.
  (if (not (read-list-isempty lyskom-to-do-list))
      (progn
	(read-list-enter-first
	   (read-list->first lyskom-to-do-list)
	   lyskom-reading-list)

	;; Tell server which conf the user is reading.
	(let ((conf-stat (read-info->conf-stat
			  (read-list->first lyskom-reading-list))))
	  (when conf-stat
	    (lyskom-enter-conf
	     conf-stat 
	     (read-list->first lyskom-reading-list))
	    (lyskom-set-mode-line conf-stat))))
    (lyskom-insert-string 'all-conf-unread-r)
    (lyskom-set-mode-line (lyskom-get-string 'all-conf-unread-s))))


(defun lyskom-maybe-move-unread (bury)
  "Empty the reading list.
If the argument BURY is non-nil and there are unread artilces left in the
reading list then the conf is inserted last in the to do list."
  (if (not (read-list-isempty lyskom-reading-list))
      (progn
	(if bury
	    (let ((conf-no nil)
		  (r 0))
	      (while (and (not conf-no)
			  (< r (read-list-length lyskom-reading-list)))
		(if (eq (read-info->type (read-list->nth lyskom-reading-list 
							 r))
			'CONF)
		    (setq conf-no (conf-stat->conf-no 
				   (read-info->conf-stat
				    (read-list->nth lyskom-reading-list r))))
		  (++ r)))
	      (if conf-no
		  (progn
		    (read-list-delete-read-info conf-no lyskom-to-do-list)
		    (read-list-enter-first (read-list->nth lyskom-reading-list
							   r)
					   lyskom-to-do-list)
		    (read-list-rotate lyskom-to-do-list)))))
	(set-read-list-empty lyskom-reading-list))))


(defun lyskom-enter-conf (conf-stat read-info)
  "Tell server which conf the user is reading.
Prints the name and amount of unread in the conference we just went to 
according to the value of kom-print-number-of-unread-on-entrance.
Args: CONF-STAT READ-INFO"
  (initiate-pepsi 'main nil (conf-stat->conf-no conf-stat))
  (setq lyskom-current-conf (conf-stat->conf-no conf-stat))
  (let ((num-unread (length (text-list->texts
			     (read-info->text-list
			      read-info)))))
    (lyskom-format-insert (if (not kom-print-number-of-unread-on-entrance)
			      'enter-conf
			    (if (= num-unread 1)
				'one-unread
			      'several-unread))
			  conf-stat
			  num-unread)))
  

(defun lyskom-put-back-on-to-do-list (read-list low-priority)
  "Add the conferences on READ-LIST on lyskom-to-do-list.
Alter the priority to kom-low-priority if LOW-PRIORITY is non-nil."
  (lyskom-traverse
      to-read (read-list->all-entries read-list)
    (if (or (eq 'CONF (read-info->type to-read))
	    (eq 'REVIEW-MARK (read-info->type to-read)))
	;; Only unread conferences and viewings of marked texts
	;; are put back on the to-do-list.
	;; E. g. unread comments to a text are not put back since they
	;; are anyhow present on a 'CONF-item's text-list.
	(progn
	  (if (and kom-low-priority
		   low-priority)
	      (set-read-info->priority to-read kom-low-priority))
	  (read-list-enter-read-info to-read
				     lyskom-to-do-list
				     (not low-priority))))))


;;;================================================================

;;; in vars.el:
;(defvar lyskom-sessions-with-unread nil
;  "Global variable. List of lyskom-sessions with unread articles.")
;;;Must be called after lyskom-get-string is defined. Also after running 
;;;load hooks.
;;;(or (assq 'lyskom-sessions-with-unread minor-mode-alist)
;;;    (setq minor-mode-alist (cons (list 'lyskom-sessions-with-unread 
;;;			       		  (lyskom-get-string 'mode-line-unread))
;;;				 minor-mode-alist)))


(defun lyskom-set-mode-line (&optional conf)
  "Sets mode-line-conf-name to the name of the optional argument conf CONF.
CONF can be a a conf-stat or a string."
  (let ((name (cond
	       ((null conf) 
		(if (zerop lyskom-current-conf)
		    (lyskom-get-string 'not-present-anywhere)
		  (initiate-get-conf-stat 'modeline 'lyskom-set-mode-line
					  lyskom-current-conf)
		  nil))
	       ((stringp conf) conf)
	       ((lyskom-conf-stat-p conf)
		(conf-stat->name conf))
	       (t "")))
	(unread -1)
	(total-unread 0)
	(letters 0)
	(len 0)
	(read-info-list nil))

    (if (null name)
	nil				; We didn't have the name.

      ;; Set unread to the number of unread texts in CONF.
      (if (lyskom-conf-stat-p conf)
	  (progn
	    (setq read-info-list 
		  (read-list->all-entries lyskom-to-do-list))

	    ;; This was weird. Someone had begun to write an if, but
	    ;; this was all there was: (if 
	    (while read-info-list
	      (if (read-info->conf-stat (car read-info-list))
		  (progn
		    (setq len (length (text-list->texts 
				       (read-info->text-list 
					(car read-info-list)))))
		    (if (= (conf-stat->conf-no conf)
			   (conf-stat->conf-no 
			    (read-info->conf-stat (car read-info-list))))
			(setq unread len))
		    (if (= lyskom-pers-no
			   (conf-stat->conf-no 
			    (read-info->conf-stat (car read-info-list))))
			(setq letters len))
		    (setq total-unread (+ total-unread len))))
	      (setq read-info-list (cdr read-info-list))))))
      (if (= unread -1)
	  (setq unread 0))

      (if (null name)
	  nil
	(setq mode-line-conf-name 
	      (substring (concat
			  (if (lyskom-conf-stat-p conf)
			      (if (> lyskom-session-priority 0)
				  (format "(%d/%d:%d) "
					  unread total-unread
					  lyskom-session-priority)
				(format "(%d/%d) " unread total-unread))
			    "")
			  name
			  (make-string 27 ? ))
			 0 27))
	(if (not kom-emacs-knows-iso-8859-1)
	    (setq mode-line-conf-name
		  (iso-8859-1-to-swascii mode-line-conf-name))))

      (if (zerop total-unread)
	  (setq lyskom-sessions-with-unread
		(delq lyskom-proc lyskom-sessions-with-unread))
	(or (assq lyskom-proc lyskom-sessions-with-unread)
	    (setq lyskom-sessions-with-unread
		  (cons lyskom-proc lyskom-sessions-with-unread))))
      (if (zerop letters)
	  (setq lyskom-sessions-with-unread-letters
		(delq lyskom-proc lyskom-sessions-with-unread-letters))
	(or (assq lyskom-proc lyskom-sessions-with-unread-letters)
	    (setq lyskom-sessions-with-unread-letters
		  (cons lyskom-proc lyskom-sessions-with-unread-letters)))))
  (force-mode-line-update))


;;; ================================================================

;;; +++Where should this be moved???


(defun lyskom-member-p (conf-no)
  "Returns non-nil if conference CONF-NO is present on lyskom-membership.
The value is actually the membership for the conference."
  (let ((list lyskom-membership)
	(found nil))
    (while (and (not found) (not (null list)))
      (if (= conf-no (membership->conf-no (car list)))
	  (setq found (car list)))
      (setq list (cdr list)))
    found))


;;; ================================================================
;;; +++ Where shall this function move?

(defun lyskom-return-time (time)
  "Return a string containing the time TIME."
  (lyskom-format 'time-yyyy-mm-dd-hh-mm
	  (+ (time->year time) 1900)
	  (1+ (time->mon  time))
	  (time->mday time)
	  (time->hour time)
	  (time->min  time)))


;;;; ================================================================
;;;;                   Scrolling and text insertion.


(defun lyskom-trim-buffer ()
  "Trim the size of a lyskom buffer to lyskom-max-buffer-size"
  (save-excursion
    (if (and kom-max-buffer-size
	     (> (buffer-size) kom-max-buffer-size))
	(let ((delchars (- (buffer-size) kom-max-buffer-size)))
	  (goto-char (point-min))
	  (while (< (point) delchars)
	    (forward-line 1))
	  (delete-region (point-min) (point))))))

(defun lyskom-scroll ()
  "Scroll screen if necessary.
The position lyskom-last-viewed will always remain visible."
  ;; Find a window to scroll. Scroll the selected window if that shows LysKOM.
  ;; Otherwise scroll any window currently showing LysKOM.
  (let ((win
	 (cond
	  ((eq (window-buffer (selected-window)) (current-buffer))
	   (selected-window))
	  (t				;(get-buffer-window (current-buffer))
	   nil))))
    (if (and win			;Do nothing if no window showed LysKOM.
	     (not (pos-visible-in-window-p (point-max))))
	(progn
	  (goto-char (point-max))
	  (recenter -1)
	  (if (not (pos-visible-in-window-p lyskom-last-viewed))
	      (progn
		(set-window-start win lyskom-last-viewed)
		(move-to-window-line -1)
		(vertical-motion 1)
		(if (not (pos-visible-in-window-p))
		    (forward-char -1))))))))
	

(defun lyskom-insert (string)
  "Insert STRING last in current buffer.
Leaves the point at the end of the buffer if possible without
scrolling past lyskom-last-viewed (generally the most recent prompt.)
Leaves the point at the end of the window if not possible. If buffer
is not on screen then doesn't move point.
The text is converted according to the value of kom-emacs-knows-iso-8859-1."
  (goto-char (point-max))
  (let ((buffer-read-only nil))
    (insert (if kom-emacs-knows-iso-8859-1
                string
              (iso-8859-1-to-swascii string))))
  (lyskom-trim-buffer)
  (let ((window (get-buffer-window (current-buffer))))
    (if window
        (if (pos-visible-in-window-p (point) window)
            nil
          (and kom-continuous-scrolling (lyskom-scroll))))))


(defun lyskom-insert-at-point (string)
  "Insert STRING in the current buffer at point.
The text is converted according to the value of
kom-emacs-knows-iso-8859-1."
  (let ((buffer-read-only nil))
    (insert (if kom-emacs-knows-iso-8859-1
                string
              (iso-8859-1-to-swascii string))))
  (lyskom-trim-buffer))  


(defun lyskom-insert-before-prompt (string)
  "Insert STRING just before the prompt of if no prompt then just buffers.
If prompt on screen then do the scroll if necessary.
The strings buffered are printed before the prompt by lyskom-print-prompt."
  (lyskom-do-insert-before-prompt string))

(defun lyskom-do-insert-before-prompt (string)
  (cond
   ((and lyskom-executing-command
         (not (eq lyskom-is-waiting t)))
    ;; Don't insert the string until the current command is finished.
    (if (null lyskom-to-be-printed-before-prompt)
        (setq lyskom-to-be-printed-before-prompt (lyskom-queue-create)))
    (lyskom-queue-enter lyskom-to-be-printed-before-prompt 
                        (list string)))
   (t (save-excursion
    (let ((oldpoint (if (/= (point) (point-max)) (point) nil)))
      (goto-char (point-max))
      (let* ((window (get-buffer-window (current-buffer)))
             (pv (and window
                      (pos-visible-in-window-p (point) window))))
        (beginning-of-line)
        (let ((buffer-read-only nil)
              (start (point)))
          (insert (if kom-emacs-knows-iso-8859-1
                      string
                    (iso-8859-1-to-swascii string))))
        (goto-char (point-max))
        (if (and pv
                 (eq window (selected-window))
                 (not (pos-visible-in-window-p (point) window)))
              (recenter -1))

        (if window
            (if (pos-visible-in-window-p (point) window)
                nil
              (goto-char (window-start window))
              (end-of-line (1- (window-height window)))))))))))


(defun lyskom-message (format-string &rest args)
  "Like message, but converts iso-8859/1 texts to swascii if necessary.
Args: FORMAT-STRING &rest ARGS"
  (let ((str (apply 'format format-string args)))
    (if kom-emacs-knows-iso-8859-1
	(message "%s" str)
      (message "%s" (iso-8859-1-to-swascii str)))))


(defun lyskom-error (format-string &rest args)
  "Like error, but converts iso-8859/1 texts to swascii if necessary.
Args: FORMAT-STRING &rest ARGS"
  (let ((str (apply 'format format-string args)))
    (if kom-emacs-knows-iso-8859-1
	(error "%s" str)
      (error "%s" (iso-8859-1-to-swascii str)))))


(defun lyskom-set-last-viewed ()
  (save-excursion
    (vertical-motion 0)
    (setq lyskom-last-viewed (point))))


;;; ================================================================
;;;                  Extended string formatting

;;; Author: David Byers
;;; Original code: Inge Wallin


(defvar lyskom-format-format
  "%\\(=\\)?\\(-?[0-9]+\\)?\\(#\\([0-9]+\\)\\)?\\(:\\)?\\([][@MmPpnrtsdoxc]\\)"
  "regexp matching format string parts.")

(defun lyskom-insert-string (atom)
 "Find the string corresponding to ATOM and insert it into the LysKOM buffer." 
  (lyskom-insert (lyskom-get-string atom)))

(defun lyskom-get-string (atom)
  "Get the string corresponding to ATOM and return it."
  (if (stringp atom)
      atom
    (let ((format-pair (assoc atom lyskom-strings)))
      (if (null format-pair)
	  (signal 'lyskom-internal-error 
		  (list 'lyskom-get-string
			(list atom ": string not found")))
	(cdr format-pair)))))


(defun lyskom-format (format-string &rest argl)
  (format-state->result (lyskom-do-format format-string argl)))

(defun lyskom-format-insert (format-string &rest argl)
  "Format and insert a string according to FORMAT-STRING.
The string is inserted at the end of the buffer with `lyskom-insert'."
  (let* ((state (lyskom-do-format format-string argl t))
	 (start (point-max))
	 (deferred (format-state->delayed-content state)))
    (lyskom-insert (format-state->result state))
    (while deferred
      (let ((defer-info (car deferred))
	    (m (make-marker)))
	(set-marker m (+ start (defer-info->pos defer-info)))
	(set-defer-info->pos defer-info m)			     
	(lyskom-defer-insertion defer-info)
	(setq deferred (cdr deferred))))))

(defun lyskom-format-insert-at-point (format-string &rest argl)
  "Format and insert a string according to FORMAT-STRING.
The string is inserted at point."
  (let* ((state (lyskom-do-format format-string argl t))
	 (start (point))
	 (deferred (format-state->delayed-content state)))
    (lyskom-insert-at-point (format-state->result state))
    (while deferred
      (let ((defer-info (car deferred))
	    (m (make-marker)))
	(set-marker m (+ start (defer-info->pos defer-info)))
	(set-defer-info->pos defer-info m)			     
	(lyskom-defer-insertion defer-info)
	(setq deferred (cdr deferred))))))

(defun lyskom-format-insert-before-prompt (format-string &rest argl)
  (lyskom-insert-before-prompt (format-state->result (lyskom-do-format format-string argl))))


(defun lyskom-do-format (format-string &optional argl accept-delay)
  "Do the actual formatting and return the resulting format-state."
  (let ((fmt (cond ((stringp format-string) format-string)
		   ((symbolp format-string) (lyskom-get-string 
					     format-string))))
	(state nil))
    (if (null fmt)
        (signal 'lyskom-internal-error (list 'lyskom-format-insert
                                             ": bad format string"))
      (save-excursion
        (if (and (boundp 'lyskom-buffer)
		 lyskom-buffer)
            (set-buffer lyskom-buffer))
	(condition-case error
	    (setq state (lyskom-format-aux (make-format-state
					    fmt
					    0
					    argl
					    "")
					   accept-delay))
	  (lyskom-format-error
	   (error "LysKOM internal error formatting %s: %s%s"
		  format-string (nth 1 error) (nth 2 error))))))
    state))





(defun lyskom-format-aux (format-state accept-delay)
  (let ((format-length (length (format-state->format-string format-state)))
        (arg-no nil)
        (pad-length nil)
        (format-letter nil)
        (colon-flag nil)
        (equals-flag nil)
        (abort-format nil))

    ;;
    ;;  Eat the format string bit by bit
    ;;

    (while (and (not abort-format)
                (< (format-state->start format-state)
                   format-length))

      ;;
      ;;    Look for a format letter. If there is none, finish up,
      ;;    otherwise handle each letter separately
      ;;

      (if (null (string-match lyskom-format-format
                              (format-state->format-string format-state)
                              (format-state->start format-state)))
          (progn
            (set-format-state->result 
             format-state
             (concat (format-state->result format-state)
                     (substring (format-state->format-string format-state)
                                (format-state->start format-state))))
            (set-format-state->start format-state
                                     (length (format-state->format-string
                                              format-state))))

        ;;
        ;; A format letter has been found
        ;;

        (set-format-state->result 
         format-state
         (concat (format-state->result format-state)
                 (substring (format-state->format-string format-state)
                            (format-state->start format-state)
                            (match-beginning 0))))

        (set-format-state->start format-state
                                 (match-end 0))

	(setq equals-flag (match-beginning 1)
	      pad-length (if (match-beginning 2)
			     (string-to-int (substring 
					     (format-state->format-string
					      format-state)
					     (match-beginning 2)
					     (match-end 2)))
			   nil)
	      arg-no (if (match-beginning 4)
			 (string-to-int (substring (format-state->format-string
						    format-state)
						   (match-beginning 4)
						   (match-end 4)))
		       nil)
	      colon-flag (match-beginning 5)
	      format-letter (if (match-beginning 6)
				(aref (format-state->format-string 
				       format-state)
				      (match-beginning 6))
			      (signal 'lyskom-internal-error
				      (list 'lyskom-format-aux 
					    (format-state->format-string
					     format-state)))))

    ;;
    ;;  If the format letter is an end-of-group letter, abort
    ;;  formatting and return to the caller.
    ;;

	(if (= ?\] format-letter)
	    (progn 
	      (setq abort-format t)
	      (set-format-state->start format-state (match-end 0)))

	  (setq format-state 
            (lyskom-format-aux-help 
             format-state
             pad-length
             arg-no
             format-letter
             equals-flag
             colon-flag
             (if (and (match-beginning 2)
                      (eq (aref (format-state->format-string format-state)
                                (match-beginning 2))
                          ?0))
                 ?0
               ? )
	     accept-delay))))))
  (lyskom-tweak-format-state format-state))


(defun lyskom-format-aux-help (format-state
                               pad-length
                               arg-no
                               format-letter
                               equals-flag
                               colon-flag
                               pad-letter
			       accept-delay)
  (let ((arg nil)
        (result nil)
        (propl nil)
        (prop-adjust-start 0)
        (prop-adjust-end 0)
        (oldpos (length (format-state->result format-state)))
        (abs-length (cond ((null pad-length) nil)
                          ((< pad-length 0) (- 0 pad-length))
                          (t pad-length))))
    (if (and arg-no 
             (< (format-state->args-length format-state) arg-no))
        (signal 'lyskom-format-error (list 'lyskom-format
                                             ": too few arguments")))
    (if arg-no
        (setq arg (nth (1- arg-no) (format-state->args format-state))))
    
    (if (format-props-p arg)        
        (setq propl (format-props->propl arg)
              arg (format-props->arg arg)))
    
    
    (cond
     ;;
     ;;  Format a string or symbol by simply inserting it into the
     ;;  result list
     ;;
     ((= format-letter ?s)
      (setq result (cond ((stringp arg) arg)
                         ((symbolp arg) (symbol-name arg))
                         (t (signal 'lyskom-format-error
                                    (list 'lyskom-format
                                          ": argument error"))))))
     ;;
     ;;  Format a number by conferting it to a string and inserting
     ;;  it into the result list
     ;;
     ((or (= format-letter ?d)
          (= format-letter ?o)
          (= format-letter ?x))
      (setq result (if (integerp arg)
                       (format (format "%%%c" format-letter)
                               arg)
                     (signal 'lyskom-internal-error
                             (list 'lyskom-format
                                   ": argument error")))))
     ;;
     ;;  Format a character by converting it to a string and inserting
     ;;  it into the result list
     ;;
     ((= format-letter ?c)
      (setq result (if (integerp arg)
                       (char-to-string arg)
                     (signal 'lyskom-internal-error
                             (list 'lyskom-format
                                   ": argument error")))))
     ;;
     ;;  Format a literal percent character by inserting a string
     ;;  containing it into the result list
     ;;
     ((= format-letter ?%)
      (setq result "%")) 
     
     ;;
     ;;  Format a text property array indicator by retreiving the
     ;;  properties from the argument list and adding a start of 
     ;;  new properties to the format state
     ;;
     ((= format-letter ?@)
      (set-format-state->delayed-propl
       format-state
       (cons (cons (length (format-state->result format-state))
                   arg)
             (format-state->delayed-propl format-state))))
     ;;
     ;;  Format a subformat list by recursively formatting the contents
     ;;  of the list, augmenting the result and format state
     ;;
     ((= format-letter ?\[)
      (setq format-state (lyskom-format-aux format-state accept-delay)
            result nil))
     ;;
     ;;  Format a conference or person name by retreiving information
     ;;  about the conference or person and inserting it as a button
     ;;  (unless the colon flag is set)
     ;;
     ((or (= format-letter ?M)
          (= format-letter ?P))
      (setq result
            (cond
             ;; The string is already supplied
             ((stringp arg) arg)

             ;; Conference 0 does not exist, and person 0 means anonymous
             ((and (integerp arg)
                   (zerop arg))
	      (setq colon-flag t)
              (lyskom-format (cond (lyskom-default-conf-string
				    lyskom-default-conf-string)
				   ((= format-letter ?P) 'person-is-anonymous)
				   (t 'conference-does-not-exist))
			     arg)
	      )

             ;; Delay the printing
             ((and accept-delay
                   kom-deferred-printing
                   (integerp arg))
              (let ((tmp (cache-get-conf-stat arg)))
                (if (null tmp)
                    (let* ((format-element
			    (concat "%#2@%"
				    (if equals-flag "=" "")
				    (if pad-length (int-to-string pad-length))
				    "#1"
				    (if colon-flag ":" "")
				    (char-to-string format-letter)))
			   (defer-info (lyskom-create-defer-info
					'get-conf-stat
					arg
					'lyskom-deferred-insert-conf
					oldpos
					(if pad-length
					    (if equals-flag
						(abs pad-length)
					      (max (length
						    lyskom-defer-indicator)
						   (abs pad-length)))
					  (length lyskom-defer-indicator))
					format-element
					lyskom-default-conf-string)))
		      (set-format-state->delayed-content
                       format-state
                       (cons defer-info
                             (format-state->delayed-content
                              format-state)))
                      lyskom-defer-indicator)
                  (setq arg tmp)
                  (conf-stat->name arg))))
	     
             ;; Find the name and return it
             ((integerp arg)
              (let ((conf-stat (blocking-do 'get-conf-stat arg)))
                (if (null conf-stat)
                    (lyskom-format (if (= format-letter ?P)
                                       'person-does-not-exist
                                     'conference-does-not-exist)
                                   arg)
                  (conf-stat->name conf-stat))))
	     
             ;; We got a conf-stat, and can use it directly
             ((lyskom-conf-stat-p arg) (conf-stat->name arg))

             ;; Something went wrong
             (t (signal 'lyskom-internal-error
                        (list 'lyskom-format
                              ": argument error")))))
      (if (and (not colon-flag)
               (or (lyskom-conf-stat-p arg)
                   (numberp arg)))
          (setq propl 
                (append
                 (lyskom-default-button (if (= format-letter ?P) 'pers 'conf)
                                        arg)
                 propl))))
     ;;
     ;;  Format a conference or person number the same way as names,
     ;;  but insert the number rather than the name
     ;;
     ((or (= format-letter ?m)
          (= format-letter ?p))
      (setq result
            (cond ((integerp arg) 
		   (int-to-string arg))
                  ((lyskom-conf-stat-p arg) 
                   (int-to-string (conf-stat->conf-no arg)))
                  (t (signal 'lyskom-internal-error
                             (list 'lyskom-format
                                   ": argument error")))))
      (if (not colon-flag)
          (setq propl 
                (append 
                 (lyskom-default-button (if (= format-letter ?p) 'pers 'conf)
                                        arg)
                 propl))))
     ;;
     ;;  Format an integer or text-stat as a text number by adding the
     ;;  by inserting a button (unless the colon flag is set)
     ;;
     ((= format-letter ?n)
      (setq result
            (cond ((integerp arg) (int-to-string arg))
                  ((lyskom-text-stat-p arg) (int-to-string
                                             (text-stat->text-no arg)))
                  (t (signal 'lyskom-internal-error
                             (list 'lyskom-format
                                   ": argument error")))))
      (if (not colon-flag)
          (setq propl
                (append (lyskom-default-button 'text arg) propl))))
     ;;
     ;;  Format a subject line by adding the subject face to the text
     ;;  properties and the subject to the result list
     ;;
     ((= format-letter ?r)
      (setq result (cond ((stringp arg) (lyskom-button-transform-text arg))
                         (t (signal 'lyskom-internal-error
                                    (list 'lyskom-format
                                          ": argument error")))))
      (if (and (not colon-flag)
               (not (lyskom-face-default-p 'kom-subject-face)))
          (setq propl (append (list 'face 'kom-subject-face) propl))))
     ;;
     ;;  Format a LysKOM text body. Currently this does nothing. It
     ;;  should parse the text for buttons
     ;;
     ((= format-letter ?t)

      ;; +++ One would want to do this before or after, but then
      ;; buttons will not be visible and other highlighting will
      ;; disappear.

      ;; (if (not colon-flag)
      ;;     (setq propl (append (list 'face 'kom-text-face) propl)))

      (setq result
            (cond ((stringp arg) (lyskom-format-text-body arg))
                  ((lyskom-text-p arg) 
                   (lyskom-format-text-body (text->text-mass arg)))
                  (t (signal 'lyskom-internal-error
                             (list 'lyskom-format
                                   ": argument error"))))))
     
     (t (signal 'lyskom-internal-error
		 (list 'lyskom-format-help format-letter))))
    
    ;;
    ;; Pad the result to the appropriate length
    ;; Fix flags so text props go in the right places anyway
    ;;
    
    (cond ((or (null pad-length)
               (null result)) nil)
          ((> abs-length (length result))
           (let ((padstring (make-string (- abs-length (length result))
                                         pad-letter)))
             (if (< pad-length 0)       ; LEFT justify
                 (progn
                   (setq prop-adjust-end (- (- abs-length (length result))))
                   (setq result (concat result padstring)))
               (progn
                 (setq prop-adjust-start (- abs-length (length result)))
                 (setq result (concat padstring result))))))
          ((and equals-flag
                (< abs-length (length result)))
           (setq result (substring result 0 abs-length))))
    
    (if result
        (progn
          (set-format-state->result 
           format-state
           (concat (format-state->result format-state)
                   result))))
    (if (and propl kom-text-properties)
        (add-text-properties
         (+ oldpos prop-adjust-start)
         (+ (length (format-state->result format-state)) prop-adjust-end)
         propl
         (format-state->result format-state))))
  format-state)




(defun lyskom-tweak-format-state (format-state) 
  (let ((dp (format-state->delayed-propl format-state)))
    (while dp
      (add-text-properties (car (car dp))
                           (length (format-state->result format-state))
                           (cdr (car dp))
                           (format-state->result format-state))
      (setq dp (cdr dp)))
    (set-format-state->delayed-propl format-state nil))
  format-state)


;;; ================================================================
;;;			 Text body formatting

;;; Author: David K}gedal
;;; This should be considered an experiment

(defvar lyskom-format-experimental nil)

(defun lyskom-format-text-body (text)
  "Format a text for insertion. Does parsing of special markers in the text."
  ;; This function is probably not written as it should
  (if lyskom-format-experimental
      (cond
       ((and (string-match "\\`html:" text)
             (condition-case e (require 'w3) (error nil)))
        (let ((tmpbuf (generate-new-buffer "lyskom-html")))
          (unwind-protect
              (save-excursion
                (set-buffer tmpbuf)
                (insert (substring text 5))
                (w3-preview-this-buffer))
            (kill-buffer tmpbuf))))
       ((and (fboundp 'format-decode-buffer)
             (string-match "\\`enriched:" text))
        (let ((tmpbuf (generate-new-buffer "lyskom-enriched")))
          (unwind-protect
              (save-excursion
                (set-buffer tmpbuf)
                (insert (substring text 10))
                (format-decode-buffer)
                (lyskom-button-transform-text (buffer-string))
                ;; (substring (buffer-string) 0 -1) ; Remove the \n
                )
            (kill-buffer tmpbuf))))
       (t (lyskom-button-transform-text text)
	))
    (lyskom-button-transform-text text)))
    


;;; ============================================================
;;;                     Beeping and feeping
;;;                     Faces and colors
;;;

(defun lyskom-beep (arg)
  "Beep. ARG is how to beep. 
nil means don't beep.
t means beep once.
A number means beep that number of times (.1 second delay between beeps).
A string means start the command kom-audio-player with the string as argument.
A symbol other than t means call it as a function."
  (cond ((null arg))
        ((eq t arg) (ding t))
        ((numberp arg) (while (> arg 0)
                         (ding t)
                         (sit-for 0.1)
                         (setq arg (1- arg))))
        ((stringp arg)
         (start-process "audio"
                        nil
                        kom-audio-player
                        arg))
        ((and (symbolp arg)
              (fboundp arg))
         (condition-case err
             (funcall arg)
           (error (message "Error in beep function")
                  (beep))))
        (t (beep))))

(defun lyskom-face-default-p (f1)
  "Return t if f1 is undefined or the default face."
  (or (not (facep f1))
      (face-equal f1 'default)))
		  

;;; ================================================================
;;;                      Iso-8859-1 converting

;;; Author: Linus Tolke Y


(defvar iso-8859-1-table 
  "
	

 !\"#$%&'()*+,-./0123456789:;<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\\]^_`abcdefghijklmnopqrstuvwxyz{|}~
	

  !c#$Y|$\"c+?!-R~C+23'u$-,10?????AAAA[][CE@EEIIIIDNOOOO\\*\\UUU^YTBaaaa{}{ce`eeiiiidnoooo|/|uuu~yty"
  "*This is a table of the chars corresponding value in SWASCII.
Used by the function iso-8859-1-to-swascii function.")


(defun iso-8859-1-to-swascii (string)
  "Returns a string without characters with code > 127.
What chars are converted to is controlled by the iso-8859-1-table."
  (let ((tmp (copy-sequence string))
        (i 0)
        (len (length string)))
    (while (< i len)
      (aset tmp i (aref iso-8859-1-table
                        (aref tmp i)))
      (setq i (1+ i)))
    tmp))


;;;; ================================================================
;;;;                         Running in buffer 

;;; Author: Linus


(defun backward-text (&optional arg)
  "Searches backwards for a text start and recenters with that text at the top."
  (interactive "p")
  (let ((paragraph-start lyskom-text-start))
    (backward-paragraph arg)))


(defun forward-text (&optional arg)
  "Searches forward for a text start and recenters with that text at the top."
  (interactive "p")
  (let ((paragraph-start lyskom-text-start))
    (forward-paragraph arg)))


(defun kom-save-text (&optional arg)
  "Saves/appends the article before point to a file.
The article is determined by a search-backward the same as backward-text 
and then a forward-text.
With an argument ARG the search is done over that number of texts.
The name of the file is read using the minibuffer and the default is kom-text."
  (interactive "p")
  (save-excursion
    (backward-text arg)
    (let ((p1 (point))
	  (p2 (progn
		(forward-text arg)
		(beginning-of-line)
		(point)))
	  (name (read-file-name 
		 (if kom-emacs-knows-iso-8859-1
		     (lyskom-format 'save-on-file-q
				    (file-name-nondirectory
				     lyskom-saved-file-name))
		   (iso-8859-1-to-swascii 
		    (lyskom-format 'save-on-file-q
				   (file-name-nondirectory
				    lyskom-saved-file-name))))
		 (file-name-directory lyskom-saved-file-name)
		 lyskom-saved-file-name
		 nil)))
      (if (file-directory-p name)
	  (setq name (concat (file-name-as-directory name)
			     (file-name-nondirectory lyskom-saved-file-name))))
      (append-to-file p1 p2
		      (expand-file-name name))
      (setq lyskom-saved-file-name name))))


;;; ================================================================
;;;                Some useful abstractions

(defsubst lyskom-membership-highest-index ()
  "Return the number of conferences the user is a member of minus 1.
This is the highest index in lyskom-membership that contains data, if
positions are counted from 0, as they are."
  (1- (length lyskom-membership)))


;;; ================================================================
;;;                             To-do


(defun lyskom-start-of-command (function &optional may-interrupt)
  "This function is run at the beginning of every LysKOM command.
It moves the cursor one line down, and +++ later it will tell the server
that the previous text has been read.

Argument FUNCTION is a string the string will be written in the buffer
on start of the command. If it is a symbol it searches for the corresponding
command name in lyskom-commands and writes this in the message buffer.

If optional argument MAY-INTERRUPT is present and non-nil,
don't signal an error if this call is interrupting another command.

Special: if lyskom-is-waiting then we are allowed to break if we set 
lyskom-is-waiting nil.

This function checks if lyskom-doing-default-command and
lyskom-first-time-around are bound. The text entered in the buffer is
chosen according to this"

  (if (and lyskom-is-waiting
           (listp lyskom-is-waiting))
      (progn
        (setq lyskom-is-waiting nil)
        (lyskom-end-of-command)))

  (setq lyskom-is-waiting nil)
  (if (and lyskom-executing-command (not may-interrupt))
      (lyskom-error "%s" (lyskom-get-string 'wait-for-prompt)))
  (if (not (and (boundp 'lyskom-doing-default-command)
                lyskom-doing-default-command))
      (cond
       (lyskom-first-time-around)
       ((stringp function) (lyskom-insert function))
       ((and function (symbolp function))
        (let ((name (lyskom-command-name function)))
          (if name (lyskom-insert name)))))
    (save-excursion
      (if (not lyskom-no-prompt)
          (let ((buffer-read-only nil))
            (goto-char (point-max))
            (delete-char (- (length lyskom-prompt-text))))))
    (lyskom-insert lyskom-prompt-executing-default-command-text))
  (setq mode-line-process (lyskom-get-string 'mode-line-working))
  (if (pos-visible-in-window-p (point-max))
      (save-excursion
        (goto-char (point-max))
        (lyskom-set-last-viewed)))
  (setq lyskom-executing-command t)
  (setq lyskom-current-command function)
  (lyskom-insert "\n")
  (if (and (eq (window-buffer (selected-window))
               (current-buffer))
           ;; (= (point) (point-max))
	   )				;Tell user something is
      (progn
	;; The following line is necessary for people who use
	;; kom-page-before-command.
        (beginning-of-line 0)           ;about to happen.
        (sit-for 0)))
                                        ;  (lyskom-scroll)
  (run-hooks 'lyskom-before-command-hook)
  (if kom-page-before-command           ;Nice with dumb terminals.
      (if (or (not (listp kom-page-before-command))
              (memq function kom-page-before-command))
          (recenter 0))))


(defun lyskom-end-of-command ()
  "Print prompt, maybe scroll, prefetch info."
  (message "")
  (let ((start 0))
    (while (and lyskom-to-be-printed-before-prompt
                (lyskom-queue->first lyskom-to-be-printed-before-prompt))
      (setq start (point-max))
      (lyskom-insert (car (lyskom-queue->first