configure.ac 26.6 KB
Newer Older
Niels Möller's avatar
Niels Möller committed
1 2
dnl -*- mode: shell-script; sh-indentation: 2; -*-

3 4
dnl Process this file with autoconf to produce a configure script.

Niels Möller's avatar
Niels Möller committed
5
AC_INIT([nettle], [3.1], [nettle-bugs@lists.lysator.liu.se])
6
AC_PREREQ(2.61)
7 8 9 10
AC_CONFIG_SRCDIR([arcfour.c])
# Needed to stop autoconf from looking for files in parent directories.
AC_CONFIG_AUX_DIR([.])

11
AC_CONFIG_HEADER([config.h])
12

Niels Möller's avatar
Niels Möller committed
13
LIBNETTLE_MAJOR=6
14
LIBNETTLE_MINOR=0
15

16
LIBHOGWEED_MAJOR=4
17
LIBHOGWEED_MINOR=0
18

19 20 21
dnl Note double square brackets, for extra m4 quoting.
MAJOR_VERSION=`echo $PACKAGE_VERSION | sed 's/^\([[^.]]*\)\..*/\1/'`
MINOR_VERSION=`echo $PACKAGE_VERSION | sed 's/^[[^.]]*\.\([[0-9]]*\).*/\1/'`
22 23 24
AC_SUBST([MAJOR_VERSION])
AC_SUBST([MINOR_VERSION])

25 26
AC_CANONICAL_HOST

27 28 29 30 31 32
# Command line options
AC_ARG_WITH(include-path,
  AC_HELP_STRING([--with-include-path], [A colon-separated list of directories to search for include files]),,
  [with_include_path=''])

if test x$with_include_path != x ; then
33
  CPPFLAGS="$CPPFLAGS -I`echo $with_include_path | sed 's/:/ -I/g'`"
34 35 36 37 38 39 40
fi

AC_ARG_WITH(lib-path,
  AC_HELP_STRING([--with-lib-path], [A colon-separated list of directories to search for libraries]),,
  [with_lib_path=''])

if test x$with_lib_path != x ; then
41
  LDFLAGS="$LDFLAGS -L`echo $with_lib_path | sed 's/:/ -L/g'`"
42 43
fi

44 45 46 47
AC_ARG_ENABLE(public-key,
  AC_HELP_STRING([--disable-public-key], [Disable public key algorithms]),,
  [enable_public_key=yes])

48
AC_ARG_ENABLE(assembler,
49 50
  AC_HELP_STRING([--disable-assembler],[Disable assembler code]),,
  [enable_assembler=yes])
51

52 53 54 55
AC_ARG_ENABLE(static,
  AC_HELP_STRING([--disable-static], [Do not build any static library]),,
  [enable_static=yes])

56
AC_ARG_ENABLE(shared,
57 58
  AC_HELP_STRING([--disable-shared], [Do not build any shared library]),,
  [enable_shared=yes])
59

60 61 62 63 64
AC_ARG_ENABLE(pic,
  AC_HELP_STRING([--disable-pic],
  [Do not try to compile library files as position independent code]),,
  [enable_pic=yes])

65 66 67
AC_ARG_ENABLE(openssl,
  AC_HELP_STRING([--disable-openssl], [Do not include openssl glue in the benchmark program]),,
  [enable_openssl=yes])
68 69 70 71 72

AC_ARG_ENABLE(gcov,
  AC_HELP_STRING([--enable-gcov], [Instrument for gcov (requires a modern gcc)]),,
  [enable_gcov=no])

Sam Thursfield's avatar
Sam Thursfield committed
73
AC_ARG_ENABLE(documentation,
74
  AC_HELP_STRING([--disable-documentation], [Omit building and installing the documentation. (default=auto)]),,
Sam Thursfield's avatar
Sam Thursfield committed
75 76
  [enable_documentation=auto])

77 78 79
AC_ARG_ENABLE(fat, AC_HELP_STRING([--enable-fat], [Enable fat library build (default=no)]),,
  [enable_fat=no])

80 81 82 83
AC_ARG_ENABLE(arm-neon,
  AC_HELP_STRING([--enable-arm-neon], [Enable ARM Neon assembly. (default=auto)]),,
  [enable_arm_neon=auto])

84 85 86 87
AC_ARG_ENABLE(x86-aesni,
  AC_HELP_STRING([--enable-x86-aesni], [Enable x86_64 aes instructions. (default=no)]),,
  [enable_x86_aesni=no])

88 89 90 91 92 93
AC_ARG_ENABLE(mini-gmp,
  AC_HELP_STRING([--enable-mini-gmp], [Enable mini-gmp, used instead of libgmp.]),,
  [enable_mini_gmp=no])

if test "x$enable_mini_gmp" = xyes ; then
  NETTLE_USE_MINI_GMP=1
94
  HOGWEED_EXTRA_SYMBOLS="mpz_*;gmp_*;mpn_*;"
95 96
else
  NETTLE_USE_MINI_GMP=0
97
  HOGWEED_EXTRA_SYMBOLS=""
98 99
fi
AC_SUBST([NETTLE_USE_MINI_GMP])
100
AC_SUBST([HOGWEED_EXTRA_SYMBOLS])
101

102 103 104 105 106
LSH_RPATH_INIT([`echo $with_lib_path | sed 's/:/ /g'` \
    `echo $exec_prefix | sed "s@^NONE@$prefix/lib@g" | sed "s@^NONE@$ac_default_prefix/lib@g"` \
    /usr/local/lib /sw/local/lib /sw/lib \
    /usr/gnu/lib /opt/gnu/lib /sw/gnu/lib /usr/freeware/lib /usr/pkg/lib])

107
# Checks for programs.
Niels Möller's avatar
Niels Möller committed
108
AC_PROG_CC
109

110 111
NETTLE_CHECK_IFUNC

112 113 114 115 116 117 118
# When $CC foo.c -o foo creates both foo and foo.exe, autoconf picks
# up the foo.exe and sets exeext to .exe. That is correct for cygwin,
# which has some kind of magic link from foo to foo.exe, but not for
# rntcl. A better check for the cygwin case would check if the
# contents of foo and foo.exe are equal; in the rntcl case, foo is a
# sh script, and foo.exe is a windows executable.

Niels Möller's avatar
Niels Möller committed
119
if test "x$CC" = xrntcl ; then
120
    AC_MSG_NOTICE([Compiling with rntcl; clearing EXEEXT and disabling assembler])
121 122
    ac_exeext=''
    ac_cv_exeext=''
Niels Möller's avatar
Niels Möller committed
123
    EXEEXT=''
124
    enable_assembler=no
125 126
fi

127 128 129 130
# Used by the testsuite only
AC_PROG_CXX

AC_LANG_PUSH(C++)
131 132
AC_TRY_COMPILE([],[return 0;],[IF_CXX=''], [IF_CXX='#'])
AC_SUBST([IF_CXX])
133 134
AC_LANG_POP

135 136
LD_VERSION_SCRIPT

Niels Möller's avatar
Niels Möller committed
137
AC_PROG_MAKE_SET
Niels Möller's avatar
Niels Möller committed
138
AC_PROG_RANLIB
139
AC_CHECK_TOOL(NM, nm, strings)
140 141
# Used only for the GNU-stack configure test.
AC_CHECK_TOOL(OBJDUMP, objdump, false)
142
AC_CHECK_TOOL(AR, ar, false)
Niels Möller's avatar
Niels Möller committed
143

144
if test "x$ac_cv_prog_cc_stdc" = xno ; then
145
  AC_ERROR([the C compiler doesn't handle ANSI-C]) #'
Niels Möller's avatar
Niels Möller committed
146
fi
147

148 149
AC_PROG_INSTALL

150 151 152 153
# According to the autoconf manual, needs install-sh from
# autoconf-2.60 or automake-1.10 to avoid races.
AC_PROG_MKDIR_P

154 155
AC_PROG_LN_S

Niels Möller's avatar
Niels Möller committed
156 157 158 159
# Compiler tests for the build system
GMP_PROG_CC_FOR_BUILD
GMP_PROG_EXEEXT_FOR_BUILD

160 161
LSH_DEPENDENCY_TRACKING

162
if test x$enable_dependency_tracking = xyes ; then
163 164 165
  # Since the makefiles use include to get the dependency files, we must
  # make sure that the files exist. We generate some more files than are
  # actually needed.
166

167
  AC_CONFIG_COMMANDS([dummy-dep-files],
168
  [(cd "$srcdir" && find . '(' -name '*.c' -o -name '*.cxx' ')' -print) \
169
 | sed 's/\.cx*$//' | (while read f; do \
170 171
      test -f "$f.o.d" || echo > "$f.o.d"; \
   done)
172
])
173
fi
174

175
# Figure out ABI. Currently, configurable only by setting CFLAGS.
176 177
ABI=standard

178
case "$host_cpu" in
179
  [x86_64 | amd64])
180
    AC_TRY_COMPILE([
181 182
#if defined(__x86_64__) || defined(__arch64__)
#error 64-bit x86
183 184
#endif
    ], [], [
185
      ABI=32
186
    ], [
187
      ABI=64
188
    ])
189
    ;;
190
  *sparc*)
191 192 193 194 195
    AC_TRY_COMPILE([
#if defined(__sparcv9) || defined(__arch64__)
#error 64-bit sparc
#endif
    ], [], [
196
      ABI=32
197
    ], [
198
      ABI=64
199
    ])
200
    ;;
201 202 203
esac

if test "x$ABI" != xstandard ; then
204
  AC_MSG_NOTICE([Compiler uses $ABI-bit ABI. To change, set CC.])
205 206 207 208 209 210 211 212 213
  if test "$libdir" = '${exec_prefix}/lib' ; then
    # Try setting a better default
    case "$host_cpu:$host_os:$ABI" in
      *:solaris*:32|*:sunos*:32)
	libdir='${exec_prefix}/lib'
	;;
      *:solaris*:64|*:sunos*:64)
	libdir='${exec_prefix}/lib/64'
	;;
214 215 216 217 218 219 220 221 222 223 224 225 226 227 228
      # Linux conventions are a mess... According to the Linux File
      # Hierarchy Standard, all architectures except IA64 puts 32-bit
      # libraries in lib, and 64-bit in lib64. Some distributions,
      # e.g., Fedora and Gentoo, adhere to this standard, while at
      # least Debian has decided to put 64-bit libraries in lib and
      # 32-bit libraries in lib32.
      
      # We try to figure out the convention, except if we're cross
      # compiling. We use lib${ABI} if /usr/lib${ABI} exists and
      # appears to not be a symlink to a different name.
      *:linux*:32|*:linux*:64)
	if test "$cross_compiling" = yes ; then
          AC_MSG_WARN([Cross compiling for linux. Can't guess if libraries go in lib${ABI} or lib.]); dnl '
	else
	  # The dash builtin pwd tries to be "helpful" and remember
229
	  # symlink names. Use -P option, and hope it's portable enough.
230
	  test -d /usr/lib${ABI} \
231
	    && (cd /usr/lib${ABI} && pwd -P | grep >/dev/null "/lib${ABI}"'$') \
232 233
	    && libdir='${exec_prefix}/'"lib${ABI}"
	fi
234 235 236 237 238 239 240 241 242 243 244
	;;
      # On freebsd, it seems 32-bit libraries are in lib32,
      # and 64-bit in lib. Don't know about "kfreebsd", does
      # it follow the Linux fhs conventions?
      *:freebsd*:32)
	libdir='${exec_prefix}/lib32'
	;;
      *:freebsd*:64)
	libdir='${exec_prefix}/lib'
	;;
      *)
245
        AC_MSG_WARN([Don't know where to install $ABI-bit libraries on this system.]); dnl '
246 247 248 249

    esac
    AC_MSG_NOTICE([Libraries to be installed in $libdir.])
  fi
250 251
fi

252 253
OPT_NETTLE_SOURCES=""

254 255
# Select assembler code
asm_path=
256 257 258
if test "x$enable_assembler" = xyes ; then
  case "$host_cpu" in
    [i?86* | k[5-8]* | pentium* | athlon])
259
      asm_path=x86
260 261 262 263
      ;;
    [x86_64 | amd64])
      if test "$ABI" = 64 ; then
	asm_path=x86_64
264 265
	if test "x$enable_fat" = xyes ; then
	  asm_path="x86_64/fat $asm_path"
266 267 268
	  OPT_NETTLE_SOURCES="fat-x86_64.c $OPT_NETTLE_SOURCES"
	elif test "x$enable_x86_aesni" = xyes ; then
	  asm_path="x86_64/aesni $asm_path"
269
	fi
270 271 272 273 274 275 276 277 278 279 280
      else
	asm_path=x86
      fi
      ;;
    *sparc*)
      if test "$ABI" = 64 ; then
	asm_path=sparc64
      else
	asm_path=sparc32
      fi
      ;;
281 282 283 284 285 286 287 288 289
    arm*)
      asm_path=arm
      if test "x$enable_fat" = xyes ; then
	asm_path="arm/fat $asm_path"
	OPT_NETTLE_SOURCES="fat-arm.c $OPT_NETTLE_SOURCES"
      else
	case "$host_cpu" in
	  armv6* | armv7*)
	    NETTLE_CHECK_ARM_NEON
290

291
	    asm_path="arm/v6 arm"
292
      
293 294 295 296 297
	    if test "x$enable_arm_neon" = xyes ; then
	      asm_path="arm/neon $asm_path"
	    fi
	    ;;
	esac
298
      fi
299
      ;;
300 301 302 303 304
    *)
      enable_assembler=no
      ;;
  esac
fi
305 306 307 308 309

# Files which replace a C source file (or otherwise don't correspond
# to a new object file).
asm_replace_list="aes-encrypt-internal.asm aes-decrypt-internal.asm \
		arcfour-crypt.asm camellia-crypt-internal.asm \
Niels Möller's avatar
Niels Möller committed
310 311
		md5-compress.asm memxor.asm memxor3.asm \
		poly1305-internal.asm \
Niels Möller's avatar
Niels Möller committed
312
		chacha-core-internal.asm \
313 314
		salsa20-crypt.asm salsa20-core-internal.asm \
		serpent-encrypt.asm serpent-decrypt.asm \
Niels Möller's avatar
Niels Möller committed
315
		sha1-compress.asm sha256-compress.asm sha512-compress.asm \
316
		sha3-permute.asm umac-nh.asm umac-nh-n.asm machine.m4"
Niels Möller's avatar
Niels Möller committed
317

318
# Assembler files which generate additional object files if they are used.
319
asm_nettle_optional_list="gcm-hash8.asm cpuid.asm \
320
  aes-encrypt-internal-2.asm aes-decrypt-internal-2.asm memxor-2.asm \
321 322
  salsa20-core-internal-2.asm sha1-compress-2.asm sha256-compress-2.asm \
  sha3-permute-2.asm sha512-compress-2.asm \
323 324
  umac-nh-n-2.asm umac-nh-2.asm"

325
asm_hogweed_optional_list=""
326
if test "x$enable_public_key" = "xyes" ; then
327
  asm_hogweed_optional_list="ecc-192-modp.asm ecc-224-modp.asm \
328
    ecc-25519-modp.asm ecc-256-redc.asm ecc-384-modp.asm ecc-521-modp.asm"
329 330
fi

331 332
OPT_NETTLE_OBJS=""
OPT_HOGWEED_OBJS=""
333

334
asm_file_list=""
335

336
if test "x$enable_assembler" = xyes ; then
337
  if test -n "$asm_path"; then
338
    AC_MSG_NOTICE([Looking for assembler files in $asm_path.])
339
    for tmp_f in $asm_replace_list ; do
340 341 342 343 344 345 346
      for asm_dir in $asm_path ; do
        if test -f "$srcdir/$asm_dir/$tmp_f"; then
	  asm_file_list="$asm_file_list $tmp_f"
          AC_CONFIG_LINKS($tmp_f:$asm_dir/$tmp_f)
	  break
        fi
      done
347
    done
348 349
    dnl Workaround for AC_CONFIG_LINKS, which complains if we use the
    dnl same destination argument $tmp_f multiple times.
350
    for tmp_n in $asm_nettle_optional_list ; do
351 352
      dnl Note extra pair of [] in sed expression
      tmp_b=`echo "$tmp_n" | sed 's/\.[[^.]]*$//'`
353 354 355 356 357 358 359 360
      for asm_dir in $asm_path ; do
	if test -f "$srcdir/$asm_dir/$tmp_n"; then
	  asm_file_list="$asm_file_list $tmp_n"
	  AC_CONFIG_LINKS($tmp_n:$asm_dir/$tmp_n)
	  while read tmp_func ; do
	    AC_DEFINE_UNQUOTED(HAVE_NATIVE_$tmp_func)
	    eval HAVE_NATIVE_$tmp_func=yes
	  done <<EOF
361
[`sed -n 's/^.*[^ 	]*PROLOGUE(_*\(nettle_\)*\([^)]*\)).*$/\2/p' < "$srcdir/$asm_dir/$tmp_n"`]
362
EOF
363
	  OPT_NETTLE_OBJS="$OPT_NETTLE_OBJS $tmp_b"'.$(OBJEXT)'
364 365 366 367 368
	  break
	fi
      done
    done	
    for tmp_h in $asm_hogweed_optional_list ; do
369 370
      dnl Note extra pair of [] in sed expression
      tmp_b=`echo "$tmp_h" | sed 's/\.[[^.]]*$//'`
371
      for asm_dir in $asm_path ; do
372 373 374
	if test -f "$srcdir/$asm_dir/$tmp_h"; then
	  asm_file_list="$asm_file_list $tmp_h"
	  AC_CONFIG_LINKS($tmp_h:$asm_dir/$tmp_h)
375 376 377 378
	  while read tmp_func ; do
	    AC_DEFINE_UNQUOTED(HAVE_NATIVE_$tmp_func)
	    eval HAVE_NATIVE_$tmp_func=yes
	  done <<EOF
379
[`sed -n 's/[^ 	]*PROLOGUE(_*\(nettle_\)*\([^)]*\)).*$/\2/p' < "$srcdir/$asm_dir/$tmp_h"`]
380
EOF
381
	  OPT_HOGWEED_OBJS="$OPT_HOGWEED_OBJS $tmp_b"'.$(OBJEXT)'
382 383 384
	  break
	fi
      done
385
    done	
386
    if test -z "$asm_file_list"; then
387 388 389 390
      enable_assembler=no
      AC_MSG_WARN([No assembler files found.])
    fi
  fi
391 392 393 394 395 396 397 398
  case "$host_os" in
    darwin*)
      ASM_RODATA='.section __TEXT,__const'
      ;;
    *)
      ASM_RODATA='.section .rodata'
      ;;
  esac
399 400
fi

401 402
AC_SUBST([OPT_NETTLE_OBJS])
AC_SUBST([OPT_HOGWEED_OBJS])
403
AC_SUBST([OPT_NETTLE_SOURCES])
404
AC_SUBST([ASM_RODATA])
405 406 407 408 409 410
if test "x$enable_assembler" = xyes ; then
  IF_ASM=''
else
  IF_ASM='#'
fi
AC_SUBST([IF_ASM])
411 412 413 414 415 416 417 418

AH_VERBATIM([HAVE_NATIVE],
[/* Define to 1 each of the following for which a native (ie. CPU specific)
    implementation of the corresponding routine exists.  */
#undef HAVE_NATIVE_ecc_192_modp
#undef HAVE_NATIVE_ecc_192_redc
#undef HAVE_NATIVE_ecc_224_modp
#undef HAVE_NATIVE_ecc_224_redc
419
#undef HAVE_NATIVE_ecc_25519_modp
420 421 422 423 424
#undef HAVE_NATIVE_ecc_256_modp
#undef HAVE_NATIVE_ecc_256_redc
#undef HAVE_NATIVE_ecc_384_modp
#undef HAVE_NATIVE_ecc_384_redc
#undef HAVE_NATIVE_ecc_521_modp
425
#undef HAVE_NATIVE_ecc_521_redc
426 427
#undef HAVE_NATIVE_gcm_hash8
#undef HAVE_NATIVE_salsa20_core
428 429
#undef HAVE_NATIVE_sha1_compress
#undef HAVE_NATIVE_sha256_compress
430 431 432 433
#undef HAVE_NATIVE_sha512_compress
#undef HAVE_NATIVE_sha3_permute
#undef HAVE_NATIVE_umac_nh
#undef HAVE_NATIVE_umac_nh_n])
434

435 436 437 438 439 440
if test "x$enable_pic" = xyes; then
    LSH_CCPIC
else
    CCPIC=''
fi
AC_SUBST(CCPIC)
441

442 443 444
IF_DLL='#'
LIBNETTLE_FILE_SRC='$(LIBNETTLE_FORLINK)'
LIBHOGWEED_FILE_SRC='$(LIBHOGWEED_FORLINK)'
445
EMULATOR=''
Martin Storsjö's avatar
Martin Storsjö committed
446
W64_ABI=no
447

448
case "$host_os" in
Martin Storsjö's avatar
Martin Storsjö committed
449
  mingw32*|cygwin*)
450 451 452 453
    # The actual DLLs, e.g. libnettle-$major-$minor.dll, are normally
    # installed into the bin dir (or more exactly $libdir/../bin, for
    # automake), while libnettle.dll.a, which is a stub file for
    # linking to the DLL, is installed into the lib dir.
Martin Storsjö's avatar
Martin Storsjö committed
454 455 456 457 458 459 460 461 462 463
    case "$host_os" in
      mingw32*)
        LIBNETTLE_FORLINK='libnettle-$(LIBNETTLE_MAJOR)-$(LIBNETTLE_MINOR).dll'
        LIBHOGWEED_FORLINK='libhogweed-$(LIBHOGWEED_MAJOR)-$(LIBHOGWEED_MINOR).dll'
        ;;
      cygwin*)
        LIBNETTLE_FORLINK='cygnettle-$(LIBNETTLE_MAJOR)-$(LIBNETTLE_MINOR).dll'
        LIBHOGWEED_FORLINK='cyghogweed-$(LIBHOGWEED_MAJOR)-$(LIBHOGWEED_MINOR).dll'
        ;;
    esac
464 465 466 467 468 469 470 471 472 473
    if test "x$cross_compiling" = xyes ; then
	case "$ABI" in
	    64)
		EMULATOR=wine64
		;;
	    *)
		EMULATOR=wine
		;;
	esac
    fi
Martin Storsjö's avatar
Martin Storsjö committed
474 475 476
    if test "x$ABI" = x64 ; then
        W64_ABI=yes
    fi
477 478
    LIBNETTLE_SONAME=''
    LIBNETTLE_FILE='libnettle.dll.a'
479
    LIBNETTLE_FILE_SRC='$(LIBNETTLE_FILE)'
480
    LIBNETTLE_LINK='$(CC) $(CFLAGS) $(LDFLAGS) -shared -Wl,--out-implib=$(LIBNETTLE_FILE) -Wl,--export-all-symbols -Wl,--enable-auto-import -Wl,--whole-archive'
481 482 483
    LIBNETTLE_LIBS='-Wl,--no-whole-archive $(LIBS)'

    LIBHOGWEED_SONAME=''
484
    LIBHOGWEED_FILE='libhogweed.dll.a'
485
    LIBHOGWEED_FILE_SRC='$(LIBHOGWEED_FILE)'
486
    LIBHOGWEED_LINK='$(CC) $(CFLAGS) $(LDFLAGS) -shared -Wl,--out-implib=$(LIBHOGWEED_FILE) -Wl,--export-all-symbols -Wl,--enable-auto-import -Wl,--whole-archive'
487
    LIBHOGWEED_LIBS='-Wl,--no-whole-archive $(LIBS) libnettle.dll.a'
488
    IF_DLL=''
489
    ;;
Grant Robinson's avatar
Grant Robinson committed
490
  darwin*)
491
    LIBNETTLE_FORLINK=libnettle.dylib
492 493
    LIBNETTLE_SONAME='libnettle.$(LIBNETTLE_MAJOR).dylib'
    LIBNETTLE_FILE='libnettle.$(LIBNETTLE_MAJOR).$(LIBNETTLE_MINOR).dylib'
494
    LIBNETTLE_LINK='$(CC) $(CFLAGS) -dynamiclib $(LDFLAGS) -install_name ${libdir}/$(LIBNETTLE_SONAME) -compatibility_version $(LIBNETTLE_MAJOR) -current_version $(LIBNETTLE_MAJOR).$(LIBNETTLE_MINOR)'
495 496
    LIBNETTLE_LIBS=''

497
    LIBHOGWEED_FORLINK=libhogweed.dylib
498 499
    LIBHOGWEED_SONAME='libhogweed.$(LIBHOGWEED_MAJOR).dylib'
    LIBHOGWEED_FILE='libhogweed.$(LIBHOGWEED_MAJOR).$(LIBHOGWEED_MINOR).dylib'
500
    LIBHOGWEED_LINK='$(CC) $(CFLAGS) -dynamiclib -L. $(LDFLAGS) -install_name ${libdir}/$(LIBHOGWEED_SONAME) -compatibility_version $(LIBHOGWEED_MAJOR) -current_version $(LIBHOGWEED_MAJOR).$(LIBHOGWEED_MINOR)'
501
    LIBHOGWEED_LIBS='-lnettle $(LIBS)'
Grant Robinson's avatar
Grant Robinson committed
502
    ;;
503 504 505 506 507 508 509
  solaris*)
    # Sun's ld uses -h to set the soname, and this option is passed
    # through by both Sun's compiler and gcc. Might not work with GNU
    # ld, but it's unusual to use GNU ld on Solaris.
    LIBNETTLE_FORLINK=libnettle.so
    LIBNETTLE_SONAME='$(LIBNETTLE_FORLINK).$(LIBNETTLE_MAJOR)'
    LIBNETTLE_FILE='$(LIBNETTLE_SONAME).$(LIBNETTLE_MINOR)'
510
    LIBNETTLE_LINK='$(CC) $(CFLAGS) $(LDFLAGS) -G -h $(LIBNETTLE_SONAME)'
511 512 513 514 515
    LIBNETTLE_LIBS=''

    LIBHOGWEED_FORLINK=libhogweed.so
    LIBHOGWEED_SONAME='$(LIBHOGWEED_FORLINK).$(LIBHOGWEED_MAJOR)'
    LIBHOGWEED_FILE='$(LIBHOGWEED_SONAME).$(LIBHOGWEED_MINOR)'
516
    LIBHOGWEED_LINK='$(CC) $(CFLAGS) $(LDFLAGS) -G -h $(LIBHOGWEED_SONAME)'
517
    LIBHOGWEED_LIBS='libnettle.so $(LIBS)'
518
    ;;
519
  *)
520 521 522
    LIBNETTLE_FORLINK=libnettle.so
    LIBNETTLE_SONAME='$(LIBNETTLE_FORLINK).$(LIBNETTLE_MAJOR)'
    LIBNETTLE_FILE='$(LIBNETTLE_SONAME).$(LIBNETTLE_MINOR)'
523
    LIBNETTLE_LINK='$(CC) $(CFLAGS) $(LDFLAGS) -shared -Wl,-soname=$(LIBNETTLE_SONAME)'
524 525
    LIBNETTLE_LIBS=''

526
    LIBHOGWEED_FORLINK=libhogweed.so
527 528
    LIBHOGWEED_SONAME='$(LIBHOGWEED_FORLINK).$(LIBHOGWEED_MAJOR)'
    LIBHOGWEED_FILE='$(LIBHOGWEED_SONAME).$(LIBHOGWEED_MINOR)'
529
    LIBHOGWEED_LINK='$(CC) $(CFLAGS) $(LDFLAGS) -shared -Wl,-soname=$(LIBHOGWEED_SONAME)'
530 531 532 533
    # Requested by debian, to make linking with only -lhogweed work
    # (does not work in general, e.g., with static linking all of
    # -lhogweed -lgmp -lnettle are still required). Also makes dlopen
    # of libhogweed.so work, without having to use RTLD_GLOBAL.
534
    LIBHOGWEED_LIBS='libnettle.so $(LIBS)'
535 536
    ;;
esac
537

538
ASM_SYMBOL_PREFIX=''
539
ASM_ELF_STYLE='no'
540
ASM_COFF_STYLE='no'
541 542 543
# GNU as default is to use @
ASM_TYPE_FUNCTION='@function'
ASM_TYPE_PROGBITS='@progbits'
544
ASM_MARK_NOEXEC_STACK=''
545
ASM_ALIGN_LOG=''
546 547 548 549 550 551 552

if test x$enable_assembler = xyes ; then
  AC_CACHE_CHECK([if globals are prefixed by underscore],
  nettle_cv_asm_underscore,
  [ # Default is no underscore
    nettle_cv_asm_underscore=no
    AC_COMPILE_IFELSE(
553
      [AC_LANG_SOURCE([int a_global_symbol;])],
554
      [ $NM conftest.$OBJEXT >conftest.out
555 556 557 558 559
        if grep _a_global_symbol conftest.out >/dev/null ; then
          nettle_cv_asm_underscore=yes
        elif grep a_global_symbol conftest.out >/dev/null ; then
          nettle_cv_asm_underscore=no
        else
560
          AC_MSG_WARN([nm does not list a_global_symbol at all])
561 562
	fi],
      [AC_MSG_WARN([test program with a single global could not be compiled!?])])])
563
  if test x$nettle_cv_asm_underscore = xyes ; then
564
    ASM_SYMBOL_PREFIX='_'
565
  fi
566

567 568 569
  AC_CACHE_CHECK([for ELF-style .type,%function pseudo-ops],
    [nettle_cv_asm_type_percent_function],
    [GMP_TRY_ASSEMBLE([
570 571
.text
.globl foo
572
.type foo,%function
573 574 575 576
foo:
.Lend:

.size foo, .Lend - foo
577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596
],
       [nettle_cv_asm_type_percent_function=yes],
       [nettle_cv_asm_type_percent_function=no])])

dnl Needs double quote for the # character
  AC_CACHE_CHECK([[for ELF-style .type,#function pseudo-ops]],
    [nettle_cv_asm_type_hash_function],
    [GMP_TRY_ASSEMBLE([
.text
.globl foo
.type foo,#function
foo:
.Lend:

.size foo, .Lend - foo
],
       [nettle_cv_asm_type_hash_function=yes],
       [nettle_cv_asm_type_hash_function=no])])

  if test x$nettle_cv_asm_type_percent_function = xyes ; then
597
    ASM_ELF_STYLE='yes'
598
    ASM_TYPE_FUNCTION='%function'
599
    ASM_TYPE_PROGBITS='%progbits'
600 601 602 603
  else
    if test x$nettle_cv_asm_type_hash_function = xyes ; then
      ASM_ELF_STYLE='yes'
      ASM_TYPE_FUNCTION='#function'
604
      ASM_TYPE_PROGBITS='#progbits'
605
    fi
606
  fi
607

608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624
  AC_CACHE_CHECK([for COFF-style .type directive],
    [nettle_cv_asm_coff_type],
      [GMP_TRY_ASSEMBLE([
.text
.globl _foo
.def _foo
.scl 2
.type 32
.endef
_foo:
],
        [nettle_cv_asm_coff_type=yes],
        [nettle_cv_asm_coff_type=no])])
  if test "x$nettle_cv_asm_coff_type" = "xyes" ; then
    ASM_COFF_STYLE=yes
  fi

625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647
  AC_CACHE_CHECK([if we should use a .note.GNU-stack section],
  nettle_cv_asm_gnu_stack,
  [ # Default
    nettle_cv_asm_gnu_stack=no

    cat >conftest.c <<EOF
int foo() { return 0; }
EOF
    nettle_compile="$CC $CFLAGS $CPPFLAGS -c conftest.c >conftest.out 2>&1"
    if AC_TRY_EVAL(nettle_compile); then
      cat conftest.out >&AC_FD_CC
      $OBJDUMP -x conftest.o | grep '\.note\.GNU-stack' > /dev/null \
      && nettle_cv_asm_gnu_stack=yes
    else
      cat conftest.out >&AC_FD_CC
      echo "configure: failed program was:" >&AC_FD_CC
      cat conftest.s >&AC_FD_CC
    fi
    rm -f conftest.*])
  if test x$nettle_cv_asm_gnu_stack = xyes ; then
    ASM_MARK_NOEXEC_STACK='.section .note.GNU-stack,"",TYPE_PROGBITS'
  fi

648 649 650 651 652 653 654
  AC_CACHE_CHECK([if .align assembly directive is logarithmic],
    [nettle_cv_asm_align_log],
    [GMP_TRY_ASSEMBLE([
.align 3
],
       [nettle_cv_asm_align_log=yes],
       [nettle_cv_asm_align_log=no])])
655
  ASM_ALIGN_LOG="$nettle_cv_asm_align_log"
656 657 658
fi

AC_SUBST(ASM_SYMBOL_PREFIX)
659
AC_SUBST(ASM_ELF_STYLE)
660
AC_SUBST(ASM_COFF_STYLE)
661
AC_SUBST(ASM_TYPE_FUNCTION)
662
AC_SUBST(ASM_TYPE_PROGBITS)
663
AC_SUBST(ASM_MARK_NOEXEC_STACK)
664
AC_SUBST(ASM_ALIGN_LOG)
Martin Storsjö's avatar
Martin Storsjö committed
665
AC_SUBST(W64_ABI)
666
AC_SUBST(EMULATOR)
667

668 669 670 671 672
AC_SUBST(LIBNETTLE_MAJOR)
AC_SUBST(LIBNETTLE_MINOR)
AC_SUBST(LIBNETTLE_FORLINK)
AC_SUBST(LIBNETTLE_SONAME)
AC_SUBST(LIBNETTLE_FILE)
673
AC_SUBST(LIBNETTLE_FILE_SRC)
674 675 676
AC_SUBST(LIBNETTLE_LINK)
AC_SUBST(LIBNETTLE_LIBS)

Niels Möller's avatar
Niels Möller committed
677 678 679 680 681
AC_SUBST(LIBHOGWEED_MAJOR)
AC_SUBST(LIBHOGWEED_MINOR)
AC_SUBST(LIBHOGWEED_FORLINK)
AC_SUBST(LIBHOGWEED_SONAME)
AC_SUBST(LIBHOGWEED_FILE)
682
AC_SUBST(LIBHOGWEED_FILE_SRC)
Niels Möller's avatar
Niels Möller committed
683 684
AC_SUBST(LIBHOGWEED_LINK)
AC_SUBST(LIBHOGWEED_LIBS)
Niels Möller's avatar
Niels Möller committed
685

Niels Möller's avatar
Niels Möller committed
686
AC_PATH_PROG(M4, m4, m4)
687

688 689 690 691
if test "x$enable_gcov" = "xyes"; then
  CFLAGS="$CFLAGS -ftest-coverage -fprofile-arcs"
fi

692
# Checks for typedefs, structures, and compiler characteristics.
Niels Möller's avatar
Niels Möller committed
693
AC_C_CONST
Niels Möller's avatar
Niels Möller committed
694 695 696 697
AC_C_INLINE
AC_TYPE_UID_T
AC_TYPE_SIZE_T
AC_HEADER_TIME
Niels Möller's avatar
Niels Möller committed
698
AC_CHECK_SIZEOF(long)
699
AC_CHECK_SIZEOF(size_t)
Niels Möller's avatar
Niels Möller committed
700

701
AC_CHECK_HEADERS([openssl/blowfish.h openssl/des.h openssl/cast.h openssl/aes.h openssl/ecdsa.h],,
702 703 704
[enable_openssl=no
 break])

705 706
AC_CHECK_HEADERS([valgrind/memcheck.h])

Niels Möller's avatar
Niels Möller committed
707
LSH_FUNC_ALLOCA
Niels Möller's avatar
Niels Möller committed
708
LSH_FUNC_STRERROR
709 710 711
# getenv_secure is used for fat overrides,
# getline is used in the testsuite
AC_CHECK_FUNCS(secure_getenv getline)
Niels Möller's avatar
Niels Möller committed
712
AC_C_BIGENDIAN
Niels Möller's avatar
Niels Möller committed
713

Niels Möller's avatar
Niels Möller committed
714
LSH_GCC_ATTRIBUTES
Niels Möller's avatar
Niels Möller committed
715

716 717
# According to Simon Josefsson, looking for uint32_t and friends in
# sys/types.h is needed on some systems, in particular cygwin.
718
AX_CREATE_STDINT_H([nettle-stdint.h], [sys/types.h])
719

Niels Möller's avatar
Niels Möller committed
720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742 743
# Check for file locking. We (AC_PROG_CC?) have already checked for
# sys/types.h and unistd.h.
AC_CACHE_CHECK([for fcntl file locking],
		nettle_cv_fcntl_locking,
[AC_TRY_COMPILE([
#if HAVE_SYS_TYPES_H
# include <sys/types.h>
#endif
#if HAVE_UNISTD_H
# include <unistd.h>
#endif
#include <fcntl.h>
],[
int op = F_SETLKW;
struct flock fl;
],
nettle_cv_fcntl_locking=yes,
nettle_cv_fcntl_locking=no)])

AH_TEMPLATE([HAVE_FCNTL_LOCKING], [Define if fcntl file locking is available])
if test "x$nettle_cv_fcntl_locking" = "xyes" ; then
  AC_DEFINE(HAVE_FCNTL_LOCKING)
fi

744
# Checks for libraries
745
if test "x$enable_public_key" = "xyes" ; then
746 747 748 749 750 751 752 753 754 755
  if test "x$enable_mini_gmp" = "xno" ; then
    AC_CHECK_LIB(gmp, __gmpz_getlimbn,,
        [AC_MSG_WARN(
    [GNU MP not found, or not 3.1 or up, see http://gmplib.org/.
    Support for public key algorithms will be unavailable.])]
        enable_public_key=no)
  
    # Add -R flags needed to run programs linked with gmp
    LSH_RPATH_FIX
  fi
756 757
fi

758
nettle_cv_gmp_numb_bits=0
759 760
if test "x$enable_public_key" = "xyes" ; then
  # Check for gmp limb size
761 762 763 764 765 766 767 768 769
  if test "x$enable_mini_gmp" = "xyes" ; then
    AC_MSG_CHECKING([for mini-gmp limb size])
    # With mini-gmp, mp_limb_t is always unsigned long.
    AC_COMPUTE_INT(nettle_cv_gmp_numb_bits, [(sizeof(unsigned long) * CHAR_BIT)],
        [#include <limits.h>],
        [AC_MSG_FAILURE([cannot find value of GMP_NUMB_BITS])])
  
    AC_MSG_RESULT([$nettle_cv_gmp_numb_bits bits])
  else
770 771 772 773 774 775 776 777
    AC_MSG_CHECKING([for GMP limb size])
    AC_COMPUTE_INT(nettle_cv_gmp_numb_bits, [GMP_NUMB_BITS],
        [#include <gmp.h>],
        [AC_MSG_FAILURE([cannot find value of GMP_NUMB_BITS])])
  
    AC_MSG_RESULT([$nettle_cv_gmp_numb_bits bits])
  fi
fi
Niels Möller's avatar
Niels Möller committed
778

779 780 781
GMP_NUMB_BITS="$nettle_cv_gmp_numb_bits"
AC_SUBST([GMP_NUMB_BITS])

782 783
AH_TEMPLATE([WITH_HOGWEED], [Defined if public key features are enabled])

784
if test "x$enable_public_key" = xyes ; then
785 786 787 788 789 790
  AC_DEFINE(WITH_HOGWEED)
  IF_HOGWEED=''
else
  IF_HOGWEED='#'
fi

791 792 793 794 795 796
if test "x$enable_static" = xyes ; then
  IF_STATIC=''
else
  IF_STATIC='#'
fi

797 798
if test "x$enable_shared" = xyes ; then
  IF_SHARED=''
799
  IF_NOT_SHARED='#'
800
else
801
  IF_SHARED='#'
802
  IF_NOT_SHARED=''
803 804
fi

Sam Thursfield's avatar
Sam Thursfield committed
805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826
# Documentation tools
if test "x$enable_documentation" != "xno"; then
  AC_PATH_PROG(MAKEINFO, makeinfo, not-found)

  if test "x$MAKEINFO" != "xnot-found"; then
    enable_documentation=yes
    AC_SUBST(MAKEINFO)
  else
    if test "x$enable_documentation" == "xauto" ; then
      enable_documentation=no
    else
      AC_MSG_ERROR([Cannot find 'makeinfo', required for documentation.])
    fi
  fi
fi

if test "x$enable_documentation" = "xyes" ; then
  IF_DOCUMENTATION=''
else
  IF_DOCUMENTATION='#'
fi

827 828 829 830 831 832
if test "x$enable_mini_gmp" = "xyes" ; then
  IF_MINI_GMP=''
else
  IF_MINI_GMP='#'
fi
  
833
AC_SUBST(IF_HOGWEED)
834
AC_SUBST(IF_STATIC)
835
AC_SUBST(IF_SHARED)
836
AC_SUBST(IF_NOT_SHARED)
Sam Thursfield's avatar
Sam Thursfield committed
837
AC_SUBST(IF_DOCUMENTATION)
838
AC_SUBST(IF_DLL)
839
AC_SUBST(IF_MINI_GMP)
840

841 842
OPENSSL_LIBFLAGS=''

843
# Check for openssl's libcrypto (used only for benchmarking)
844 845 846 847 848 849 850
if test x$enable_openssl = xyes ; then
  AC_CHECK_LIB(crypto, BF_ecb_encrypt,
    [OPENSSL_LIBFLAGS='-lcrypto'],
    [enable_openssl=no])
fi

AH_TEMPLATE([WITH_OPENSSL],
851
	    [Define if you have openssl's libcrypto (used for benchmarking)]) dnl'
852 853 854 855

if test x$enable_openssl = xyes ; then
  AC_DEFINE(WITH_OPENSSL)
fi
856 857

AC_SUBST(OPENSSL_LIBFLAGS)
858

859
AH_BOTTOM(
860 861 862 863 864 865
[#if defined(__x86_64__) || defined(__arch64__)
# define HAVE_NATIVE_64_BIT 1
#else
/* Needs include of <limits.h> before use. */
# define HAVE_NATIVE_64_BIT (SIZEOF_LONG * CHAR_BIT >= 64)
#endif
866 867
])

868 869 870 871 872 873 874
# clock_gettime is in librt on *-*-osf5.1 and on glibc, so add -lrt to
# BENCH_LIBS if needed. On linux (tested on x86_32, 2.6.26),
# clock_getres reports ns accuracy, while in a quick test on osf
# clock_getres said only 1 millisecond.

old_LIBS="$LIBS"
AC_SEARCH_LIBS(clock_gettime, rt, [
875
  AC_DEFINE([HAVE_CLOCK_GETTIME],1,[Define if clock_gettime is available])])
876 877 878 879 880
BENCH_LIBS="$LIBS"
LIBS="$old_LIBS"

AC_SUBST(BENCH_LIBS)

Niels Möller's avatar
Niels Möller committed
881 882
# Set these flags *last*, or else the test programs won't compile
if test x$GCC = xyes ; then
883
  # Using -ggdb3 makes (some versions of) Redhat's gcc-2.96 dump core
884
  if $CC --version | grep '^2\.96$' 1>/dev/null 2>&1; then
885 886 887 888
    true
  else
    CFLAGS="$CFLAGS -ggdb3"
  fi
889
  # FIXME: It would be better to actually test if this option works and/or is needed.
Niels Möller's avatar
Niels Möller committed
890
  # Or perhaps use -funsigned-char.
891
  if $CC --version | grep 'gcc.* 4\.' 1>/dev/null 2>&1; then
892 893
    CFLAGS="$CFLAGS -Wno-pointer-sign"
  fi
894 895 896
  CFLAGS="$CFLAGS -Wall -W \
  -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes \
  -Wpointer-arith -Wbad-function-cast -Wnested-externs"
Niels Möller's avatar
Niels Möller committed
897 898 899

# Don't enable -Wcast-align as it results in tons of warnings in the
# DES code. And when using stdio.
900 901
# Don't enable -Waggregate-return, as that causes warnings for glibc
# inttypes.h.
Niels Möller's avatar
Niels Möller committed
902
fi
Niels Möller's avatar
Niels Möller committed
903

904
AC_CONFIG_FILES([config.make config.m4 Makefile bignum.h version.h])
905
AC_CONFIG_FILES([tools/Makefile testsuite/Makefile examples/Makefile])
906
AC_CONFIG_FILES([nettle.pc hogweed.pc libnettle.map libhogweed.map])
907 908

AC_OUTPUT
909

910 911 912 913 914 915 916 917 918
AC_MSG_NOTICE([summary of build options:

  Version:           ${PACKAGE_STRING}
  Host type:         ${host}
  ABI:               ${ABI}
  Assembly files:    ${asm_path:-none}
  Install prefix:    ${prefix}
  Library directory: ${libdir}
  Compiler:          ${CC}
919
  Static libraries:  ${enable_static}
920 921
  Shared libraries:  ${enable_shared}
  Public key crypto: ${enable_public_key}
922
  Using mini-gmp:    ${enable_mini_gmp}
Sam Thursfield's avatar
Sam Thursfield committed
923
  Documentation:     ${enable_documentation}
924
])