Skip to content
Snippets Groups Projects
Select Git revision
  • 47c59e94dbccf11b811b55c1af8a60101eb57e0c
  • master default protected
  • streebog
  • gost28147
  • master-updates
  • ed448
  • shake256
  • curve448
  • ecc-sqrt
  • gosthash94cp
  • cmac64
  • block16-refactor
  • siv-mode
  • cmac-layout
  • delete-des-compat
  • delete-rsa_blind
  • aes-struct-layout
  • release-3.4-fixes
  • struct-layout
  • attribute-deprecated
  • rename-data-symbols
  • nettle_3.5.1_release_20190627
  • nettle_3.5_release_20190626
  • nettle_3.5rc1
  • nettle_3.4.1_release_20181204
  • nettle_3.4.1rc1
  • nettle_3.4_release_20171119
  • nettle_3.4rc2
  • nettle_3.4rc1
  • nettle_3.3_release_20161001
  • nettle_3.2_release_20160128
  • nettle_3.1.1_release_20150424
  • nettle_3.1_release_20150407
  • nettle_3.1rc3
  • nettle_3.1rc2
  • nettle_3.1rc1
  • nettle_3.0_release_20140607
  • nettle_2.7.1_release_20130528
  • nettle_2.7_release_20130424
  • nettle_2.6_release_20130116
  • nettle_2.5_release_20120707
41 results

aes-meta.c

Blame
  • Forked from Nettle / nettle
    Source project has a limited visibility.
    list-obj-sizes.awk 1.26 KiB
    #! /usr/bin/awk -f
    
    # Run this filter on the output of
    #
    #   objdump -h libnettle.a
    
    function hex2int (hex, n, i) {
      n = 0;
      hex = tolower(hex);
      for (i = 1; i<=length(hex); i++)
        {
          n = n * 16 + index("0123456789abcdef", substr(hex,i,1)) - 1;
        }
    
      return n;
    }
    
    function output () {
      if (name)
        {
          printf "%25s %6d   %6d   %6d\n", name, text_size, data_size, rodata_size;
          text_total += text_size;
          data_total += data_size;
          rodata_total += rodata_size; 
        } 
      text_size = 0;
      data_size = 0;
      rodata_size = 0;
    }
    
    BEGIN {
        print "file                   text-size  data-size  rodata-size";
        text_total = 0;
        data_total = 0;
        rodata_total = 0;
    
        text_size = 0;
        data_size = 0;
        rodata_size = 0;
    
        name = "";
        filter = ENVIRON["FILTER"];
        if (!filter)
          filter = ".*";
        else
          printf "Filter: %s\n", filter;
    }
    
    /elf32|elf64/ {
      output();
      if ($1 ~ filter)
        {
          name = $1; text_size = data_size = rodata_size = 0;
          sub(/^[^-]*_a-/, "", name);
        }
      else
        name = "";
    }
    
    /\.text/ { text_size += hex2int($3); }
    /\.data/ { data_size += hex2int($3); }
    /\.rodata/ { rodata_size += hex2int($3);}
    
    END {
      output();
      printf "%25s %6d   %6d   %6d\n", "TOTAL", text_total, data_total, rodata_total;
    }