Skip to content
Snippets Groups Projects
Select Git revision
  • a16dd13f199e3ccb806bb4832ef4335a12ba5901
  • master default
  • support_pre_UAL_arm_asm
  • skein
  • rsa-crt-hardening
  • chacha96
  • fat-library
  • versioned-symbols
  • curve25519
  • dsa-reorg
  • aead-api
  • set_key-changes
  • poly1305
  • aes-reorg
  • nettle-2.7-fixes
  • size_t-changes
  • ecc-support
  • experimental-20050201
  • lsh-1.4.2
  • nettle_3.3_release_20161001
  • nettle_3.2_release_20160128
  • nettle_3.1.1_release_20150424
  • nettle_3.1_release_20150407
  • nettle_3.1rc3
  • nettle_3.1rc2
  • nettle_3.1rc1
  • nettle_3.0_release_20140607
  • nettle_2.7.1_release_20130528
  • nettle_2.7_release_20130424
  • nettle_2.6_release_20130116
  • nettle_2.5_release_20120707
  • converted-master-branch-to-git
  • nettle_2.4_release_20110903
  • nettle_2.3_release_20110902
  • nettle_2.2_release_20110711
  • nettle_2.1_release_20100725
  • camellia_32bit_20100720
  • nettle_2.0_release_20090608
  • nettle_1.15_release_20061128
39 results

arcfour-crypt.c

Blame
  • Forked from Nettle / nettle
    Source project has a limited visibility.
    list-obj-sizes.awk 1.26 KiB
    #! /usr/bin/awk -f
    
    # Run this filter on the output of
    #
    #   objdump -h libnettle.a
    
    function hex2int (hex, n, i) {
      n = 0;
      hex = tolower(hex);
      for (i = 1; i<=length(hex); i++)
        {
          n = n * 16 + index("0123456789abcdef", substr(hex,i,1)) - 1;
        }
    
      return n;
    }
    
    function output () {
      if (name)
        {
          printf "%25s %6d   %6d   %6d\n", name, text_size, data_size, rodata_size;
          text_total += text_size;
          data_total += data_size;
          rodata_total += rodata_size; 
        } 
      text_size = 0;
      data_size = 0;
      rodata_size = 0;
    }
    
    BEGIN {
        print "file                   text-size  data-size  rodata-size";
        text_total = 0;
        data_total = 0;
        rodata_total = 0;
    
        text_size = 0;
        data_size = 0;
        rodata_size = 0;
    
        name = "";
        filter = ENVIRON["FILTER"];
        if (!filter)
          filter = ".*";
        else
          printf "Filter: %s\n", filter;
    }
    
    /elf32|elf64/ {
      output();
      if ($1 ~ filter)
        {
          name = $1; text_size = data_size = rodata_size = 0;
          sub(/^[^-]*_a-/, "", name);
        }
      else
        name = "";
    }
    
    /\.text/ { text_size += hex2int($3); }
    /\.data/ { data_size += hex2int($3); }
    /\.rodata/ { rodata_size += hex2int($3);}
    
    END {
      output();
      printf "%25s %6d   %6d   %6d\n", "TOTAL", text_total, data_total, rodata_total;
    }