Skip to content
Snippets Groups Projects
Select Git revision
  • bc63438c23cae6d876b4c424cfbe5f37b3468475
  • master default protected
  • hpke
  • ppc-chacha-4core
  • delete-internal-name-mangling
  • master-updates
  • ppc-gcm
  • ppc-chacha-2core
  • refactor-ecc-mod
  • ppc-chacha-core
  • use-mpn_cnd-functions
  • optimize-ecc-invert
  • default-m4-quote-char
  • power-asm-wip
  • test-fat
  • chacha-3core-neon
  • x86_64-salsa20-2core
  • salsa20-2core-neon
  • bcrypt
  • arm-salsa20-chacha-vsra
  • test-shlib-dir
  • nettle_3.6_release_20200429
  • nettle_3.6rc3
  • nettle_3.6rc2
  • nettle_3.6rc1
  • nettle_3.5.1_release_20190627
  • nettle_3.5_release_20190626
  • nettle_3.5rc1
  • nettle_3.4.1_release_20181204
  • nettle_3.4.1rc1
  • nettle_3.4_release_20171119
  • nettle_3.4rc2
  • nettle_3.4rc1
  • nettle_3.3_release_20161001
  • nettle_3.2_release_20160128
  • nettle_3.1.1_release_20150424
  • nettle_3.1_release_20150407
  • nettle_3.1rc3
  • nettle_3.1rc2
  • nettle_3.1rc1
  • nettle_3.0_release_20140607
41 results

base16.h

Blame
  • Forked from Nettle / nettle
    Source project has a limited visibility.
    list-obj-sizes.awk 1.26 KiB
    #! /usr/bin/awk -f
    
    # Run this filter on the output of
    #
    #   objdump -h libnettle.a
    
    function hex2int (hex, n, i) {
      n = 0;
      hex = tolower(hex);
      for (i = 1; i<=length(hex); i++)
        {
          n = n * 16 + index("0123456789abcdef", substr(hex,i,1)) - 1;
        }
    
      return n;
    }
    
    function output () {
      if (name)
        {
          printf "%25s %6d   %6d   %6d\n", name, text_size, data_size, rodata_size;
          text_total += text_size;
          data_total += data_size;
          rodata_total += rodata_size; 
        } 
      text_size = 0;
      data_size = 0;
      rodata_size = 0;
    }
    
    BEGIN {
        print "file                   text-size  data-size  rodata-size";
        text_total = 0;
        data_total = 0;
        rodata_total = 0;
    
        text_size = 0;
        data_size = 0;
        rodata_size = 0;
    
        name = "";
        filter = ENVIRON["FILTER"];
        if (!filter)
          filter = ".*";
        else
          printf "Filter: %s\n", filter;
    }
    
    /elf32|elf64/ {
      output();
      if ($1 ~ filter)
        {
          name = $1; text_size = data_size = rodata_size = 0;
          sub(/^[^-]*_a-/, "", name);
        }
      else
        name = "";
    }
    
    /\.text/ { text_size += hex2int($3); }
    /\.data/ { data_size += hex2int($3); }
    /\.rodata/ { rodata_size += hex2int($3);}
    
    END {
      output();
      printf "%25s %6d   %6d   %6d\n", "TOTAL", text_total, data_total, rodata_total;
    }