Skip to content
Snippets Groups Projects
Select Git revision
  • a16dd13f199e3ccb806bb4832ef4335a12ba5901
  • master default protected
  • siv-mode
  • delete-des-compat
  • delete-rsa_blind
  • aes-struct-layout
  • master-updates
  • release-3.4-fixes
  • struct-layout
  • attribute-deprecated
  • rename-data-symbols
  • x86_64-sha_ni-sha256
  • ecc-params-tweak
  • delete-old-aes
  • cmac-support
  • x86_64-sha_ni-sha1
  • gcm-ctr-opt
  • ctr-opt
  • skein
  • api-opaque-fix
  • curve448
  • nettle_3.4.1_release_20181204
  • nettle_3.4.1rc1
  • nettle_3.4_release_20171119
  • nettle_3.4rc2
  • nettle_3.4rc1
  • nettle_3.3_release_20161001
  • nettle_3.2_release_20160128
  • nettle_3.1.1_release_20150424
  • nettle_3.1_release_20150407
  • nettle_3.1rc3
  • nettle_3.1rc2
  • nettle_3.1rc1
  • nettle_3.0_release_20140607
  • nettle_2.7.1_release_20130528
  • nettle_2.7_release_20130424
  • nettle_2.6_release_20130116
  • nettle_2.5_release_20120707
  • converted-master-branch-to-git
  • nettle_2.4_release_20110903
  • nettle_2.3_release_20110902
41 results

rsa-sign.c

Blame
  • Forked from Nettle / nettle
    Source project has a limited visibility.
    user_instance.pp 2.03 KiB
    # @summary Configures an mpd instance for the specified user
    #
    # Only works on systems which uses systemd, and already has a user
    # systemd unit for mpd.
    #
    # @param user
    #   User to run as, as well as owner of files
    # @param group
    #   Group for created files
    # @param user_home
    #   Home directory for user. Used in figuring out where to put
    #   configuation files.
    # @param xdg_config_home
    #   XDG configuration directory for user, used in figuring out where
    #   to put configuration files.
    # @param config_dir
    #   User specific configuration directory for mpd.
    # @param config_file
    #   User specific configuration file for mpd.
    # @param manage_dir
    #   Should the config_dir be managed by us.
    # @param mpd_conf
    #   Settings passed along to mpd::conf
    # @param service_name
    #   Name of the user (system) service
    define mpd::user_instance (
      String $user = $name,
      String $group = $user,
      String $user_home = "/home/${user}",
      String $xdg_config_home = "${user_home}/.config",
      String $config_dir = "${xdg_config_home}/mpd",
      String $config_file = "${config_dir}/mpd.conf",
      Boolean $manage_dir = true,
      Hash[String, Any] $mpd_conf = {},
      String $service_name = 'mpd',
    ) {
      if $manage_dir {
        file { $config_dir:
          ensure => directory,
          owner  => $user,
          group  => $group,
        }
      }
    
      $conf_defaults = {
        'mpd_home' => $config_dir,
      }
    
      mpd::config { "MPD instance for ${user}":
        config_file => $config_file,
        user        => undef,
        owner       => $user,
        group       => $group,
        *           => $conf_defaults + $mpd_conf,
      } ~> Exec["Restart user ${user} mpd instance"]
    
      exec { "Enable user ${user} mpd instance":
        command => "systemctl enable --machine=${user}@.host --now --user ${service_name}",
        creates => "${xdg_config_home}/systemd/user/default.target.wants/mpd.service",
        path    => ['/bin', '/usr/bin'],
      }
    
      exec { "Restart user ${user} mpd instance":
        command     => "systemctl restart --machine=${user}@.host --user ${service_name}",
        refreshonly => true,
        path        => ['/bin', '/usr/bin'],
      }
    }